include/asm-generic/vmlinux.lds.h

   1 #ifndef LOAD_OFFSET
   2 #define LOAD_OFFSET 0
   3 #endif
   4
   5 #ifndef VMLINUX_SYMBOL
   6 #define VMLINUX_SYMBOL(_sym_) _sym_
   7 #endif
   8
   9 /* Align . to a 8 byte boundary equals to maximum function alignment. */
  10 #define ALIGN_FUNCTION()  . = ALIGN(8)
  11
  12 /* The actual configuration determine if the init/exit sections
  13  * are handled as text/data or they can be discarded (which
  14  * often happens at runtime)
  15  */
  16 #ifdef CONFIG_HOTPLUG
  17 #define DEV_KEEP(sec)    *(.dev##sec)
  18 #define DEV_DISCARD(sec)
  19 #else
  20 #define DEV_KEEP(sec)
  21 #define DEV_DISCARD(sec) *(.dev##sec)
  22 #endif
  23
  24 #ifdef CONFIG_HOTPLUG_CPU
  25 #define CPU_KEEP(sec)    *(.cpu##sec)
  26 #define CPU_DISCARD(sec)
  27 #else
  28 #define CPU_KEEP(sec)
  29 #define CPU_DISCARD(sec) *(.cpu##sec)
  30 #endif
  31
  32 #if defined(CONFIG_MEMORY_HOTPLUG)
  33 #define MEM_KEEP(sec)    *(.mem##sec)
  34 #define MEM_DISCARD(sec)
  35 #else
  36 #define MEM_KEEP(sec)
  37 #define MEM_DISCARD(sec) *(.mem##sec)
  38 #endif
  39
  40
  41 /* .data section */
  42 #define DATA_DATA                                                       \
  43         *(.data)                                                        \
  44         *(.data.init.refok)                                             \
  45         *(.ref.data)                                                    \
  46         DEV_KEEP(init.data)                                             \
  47         DEV_KEEP(exit.data)                                             \
  48         CPU_KEEP(init.data)                                             \
  49         CPU_KEEP(exit.data)                                             \
  50         MEM_KEEP(init.data)                                             \
  51         MEM_KEEP(exit.data)                                             \
  52         . = ALIGN(8);                                                   \
  53         VMLINUX_SYMBOL(__start___markers) = .;                          \
  54         *(__markers)                                                    \
  55         VMLINUX_SYMBOL(__stop___markers) = .;
  56
  57 #define RO_DATA(align)                                                  \
  58         . = ALIGN((align));                                             \
  59         .rodata           : AT(ADDR(.rodata) - LOAD_OFFSET) {           \
  60                 VMLINUX_SYMBOL(__start_rodata) = .;                     \
  61                 *(.rodata) *(.rodata.*)                                 \
  62                 *(__vermagic)           /* Kernel version magic */      \
  63                 *(__markers_strings)    /* Markers: strings */          \
  64         }                                                               \
  65                                                                         \
  66         .rodata1          : AT(ADDR(.rodata1) - LOAD_OFFSET) {          \
  67                 *(.rodata1)                                             \
  68         }                                                               \
  69                                                                         \
  70         /* PCI quirks */                                                \
  71         .pci_fixup        : AT(ADDR(.pci_fixup) - LOAD_OFFSET) {        \
  72                 VMLINUX_SYMBOL(__start_pci_fixups_early) = .;           \
  73                 *(.pci_fixup_early)                                     \
  74                 VMLINUX_SYMBOL(__end_pci_fixups_early) = .;             \
  75                 VMLINUX_SYMBOL(__start_pci_fixups_header) = .;          \
  76                 *(.pci_fixup_header)                                    \
  77                 VMLINUX_SYMBOL(__end_pci_fixups_header) = .;            \
  78                 VMLINUX_SYMBOL(__start_pci_fixups_final) = .;           \
  79                 *(.pci_fixup_final)                                     \
  80                 VMLINUX_SYMBOL(__end_pci_fixups_final) = .;             \
  81                 VMLINUX_SYMBOL(__start_pci_fixups_enable) = .;          \
  82                 *(.pci_fixup_enable)                                    \
  83                 VMLINUX_SYMBOL(__end_pci_fixups_enable) = .;            \
  84                 VMLINUX_SYMBOL(__start_pci_fixups_resume) = .;          \
  85                 *(.pci_fixup_resume)                                    \
  86                 VMLINUX_SYMBOL(__end_pci_fixups_resume) = .;            \
  87         }                                                               \
  88                                                                         \
  89         /* RapidIO route ops */                                         \
  90         .rio_route        : AT(ADDR(.rio_route) - LOAD_OFFSET) {        \
  91                 VMLINUX_SYMBOL(__start_rio_route_ops) = .;              \
  92                 *(.rio_route_ops)                                       \
  93                 VMLINUX_SYMBOL(__end_rio_route_ops) = .;                \
  94         }                                                               \
  95                                                                         \
  96         /* Kernel symbol table: Normal symbols */                       \
  97         __ksymtab         : AT(ADDR(__ksymtab) - LOAD_OFFSET) {         \
  98                 VMLINUX_SYMBOL(__start___ksymtab) = .;                  \
  99                 *(__ksymtab)                                            \
 100                 VMLINUX_SYMBOL(__stop___ksymtab) = .;                   \
 101         }                                                               \
 102                                                                         \
 103         /* Kernel symbol table: GPL-only symbols */                     \
 104         __ksymtab_gpl     : AT(ADDR(__ksymtab_gpl) - LOAD_OFFSET) {     \
 105                 VMLINUX_SYMBOL(__start___ksymtab_gpl) = .;              \
 106                 *(__ksymtab_gpl)                                        \
 107                 VMLINUX_SYMBOL(__stop___ksymtab_gpl) = .;               \
 108         }                                                               \
 109                                                                         \
 110         /* Kernel symbol table: Normal unused symbols */                \
 111         __ksymtab_unused  : AT(ADDR(__ksymtab_unused) - LOAD_OFFSET) {  \
 112                 VMLINUX_SYMBOL(__start___ksymtab_unused) = .;           \
 113                 *(__ksymtab_unused)                                     \
 114                 VMLINUX_SYMBOL(__stop___ksymtab_unused) = .;            \
 115         }                                                               \
 116                                                                         \
 117         /* Kernel symbol table: GPL-only unused symbols */              \
 118         __ksymtab_unused_gpl : AT(ADDR(__ksymtab_unused_gpl) - LOAD_OFFSET) { \
 119                 VMLINUX_SYMBOL(__start___ksymtab_unused_gpl) = .;       \
 120                 *(__ksymtab_unused_gpl)                                 \
 121                 VMLINUX_SYMBOL(__stop___ksymtab_unused_gpl) = .;        \
 122         }                                                               \
 123                                                                         \
 124         /* Kernel symbol table: GPL-future-only symbols */              \
 125         __ksymtab_gpl_future : AT(ADDR(__ksymtab_gpl_future) - LOAD_OFFSET) { \
 126                 VMLINUX_SYMBOL(__start___ksymtab_gpl_future) = .;       \
 127                 *(__ksymtab_gpl_future)                                 \
 128                 VMLINUX_SYMBOL(__stop___ksymtab_gpl_future) = .;        \
 129         }                                                               \
 130                                                                         \
 131         /* Kernel symbol table: Normal symbols */                       \
 132         __kcrctab         : AT(ADDR(__kcrctab) - LOAD_OFFSET) {         \
 133                 VMLINUX_SYMBOL(__start___kcrctab) = .;                  \
 134                 *(__kcrctab)                                            \
 135                 VMLINUX_SYMBOL(__stop___kcrctab) = .;                   \
 136         }                                                               \
 137                                                                         \
 138         /* Kernel symbol table: GPL-only symbols */                     \
 139         __kcrctab_gpl     : AT(ADDR(__kcrctab_gpl) - LOAD_OFFSET) {     \
 140                 VMLINUX_SYMBOL(__start___kcrctab_gpl) = .;              \
 141                 *(__kcrctab_gpl)                                        \
 142                 VMLINUX_SYMBOL(__stop___kcrctab_gpl) = .;               \
 143         }                                                               \
 144                                                                         \
 145         /* Kernel symbol table: Normal unused symbols */                \
 146         __kcrctab_unused  : AT(ADDR(__kcrctab_unused) - LOAD_OFFSET) {  \
 147                 VMLINUX_SYMBOL(__start___kcrctab_unused) = .;           \
 148                 *(__kcrctab_unused)                                     \
 149                 VMLINUX_SYMBOL(__stop___kcrctab_unused) = .;            \
 150         }                                                               \
 151                                                                         \
 152         /* Kernel symbol table: GPL-only unused symbols */              \
 153         __kcrctab_unused_gpl : AT(ADDR(__kcrctab_unused_gpl) - LOAD_OFFSET) { \
 154                 VMLINUX_SYMBOL(__start___kcrctab_unused_gpl) = .;       \
 155                 *(__kcrctab_unused_gpl)                                 \
 156                 VMLINUX_SYMBOL(__stop___kcrctab_unused_gpl) = .;        \
 157         }                                                               \
 158                                                                         \
 159         /* Kernel symbol table: GPL-future-only symbols */              \
 160         __kcrctab_gpl_future : AT(ADDR(__kcrctab_gpl_future) - LOAD_OFFSET) { \
 161                 VMLINUX_SYMBOL(__start___kcrctab_gpl_future) = .;       \
 162                 *(__kcrctab_gpl_future)                                 \
 163                 VMLINUX_SYMBOL(__stop___kcrctab_gpl_future) = .;        \
 164         }                                                               \
 165                                                                         \
 166         /* Kernel symbol table: strings */                              \
 167         __ksymtab_strings : AT(ADDR(__ksymtab_strings) - LOAD_OFFSET) { \
 168                 *(__ksymtab_strings)                                    \
 169         }                                                               \
 170                                                                         \
 171         /* __*init sections */                                          \
 172         __init_rodata : AT(ADDR(__init_rodata) - LOAD_OFFSET) {         \
 173                 *(.ref.rodata)                                          \
 174                 DEV_KEEP(init.rodata)                                   \
 175                 DEV_KEEP(exit.rodata)                                   \
 176                 CPU_KEEP(init.rodata)                                   \
 177                 CPU_KEEP(exit.rodata)                                   \
 178                 MEM_KEEP(init.rodata)                                   \
 179                 MEM_KEEP(exit.rodata)                                   \
 180         }                                                               \
 181                                                                         \
 182         /* Built-in module parameters. */                               \
 183         __param : AT(ADDR(__param) - LOAD_OFFSET) {                     \
 184                 VMLINUX_SYMBOL(__start___param) = .;                    \
 185                 *(__param)                                              \
 186                 VMLINUX_SYMBOL(__stop___param) = .;                     \
 187                 VMLINUX_SYMBOL(__end_rodata) = .;                       \
 188         }                                                               \
 189         . = ALIGN((align));
 190
 191 /* RODATA provided for backward compatibility.
 192  * All archs are supposed to use RO_DATA() */
 193 #define RODATA RO_DATA(4096)
 194
 195 #define SECURITY_INIT                                                   \
 196         .security_initcall.init : AT(ADDR(.security_initcall.init) - LOAD_OFFSET) { \
 197                 VMLINUX_SYMBOL(__security_initcall_start) = .;          \
 198                 *(.security_initcall.init)                              \
 199                 VMLINUX_SYMBOL(__security_initcall_end) = .;            \
 200         }
 201
 202 /* .text section. Map to function alignment to avoid address changes
 203  * during second ld run in second ld pass when generating System.map */
 204 #define TEXT_TEXT                                                       \
 205                 ALIGN_FUNCTION();                                       \
 206                 *(.text)                                                \
 207                 *(.ref.text)                                            \
 208                 *(.text.init.refok)                                     \
 209                 *(.exit.text.refok)                                     \
 210         DEV_KEEP(init.text)                                             \
 211         DEV_KEEP(exit.text)                                             \
 212         CPU_KEEP(init.text)                                             \
 213         CPU_KEEP(exit.text)                                             \
 214         MEM_KEEP(init.text)                                             \
 215         MEM_KEEP(exit.text)
 216
 217
 218 /* sched.text is aling to function alignment to secure we have same
 219  * address even at second ld pass when generating System.map */
 220 #define SCHED_TEXT                                                      \
 221                 ALIGN_FUNCTION();                                       \
 222                 VMLINUX_SYMBOL(__sched_text_start) = .;                 \
 223                 *(.sched.text)                                          \
 224                 VMLINUX_SYMBOL(__sched_text_end) = .;
 225
 226 /* spinlock.text is aling to function alignment to secure we have same
 227  * address even at second ld pass when generating System.map */
 228 #define LOCK_TEXT                                                       \
 229                 ALIGN_FUNCTION();                                       \
 230                 VMLINUX_SYMBOL(__lock_text_start) = .;                  \
 231                 *(.spinlock.text)                                       \
 232                 VMLINUX_SYMBOL(__lock_text_end) = .;
 233
 234 #define KPROBES_TEXT                                                    \
 235                 ALIGN_FUNCTION();                                       \
 236                 VMLINUX_SYMBOL(__kprobes_text_start) = .;               \
 237                 *(.kprobes.text)                                        \
 238                 VMLINUX_SYMBOL(__kprobes_text_end) = .;
 239
 240 /* init and exit section handling */
 241 #define INIT_DATA                                                       \
 242         *(.init.data)                                                   \
 243         DEV_DISCARD(init.data)                                          \
 244         DEV_DISCARD(init.rodata)                                        \
 245         CPU_DISCARD(init.data)                                          \
 246         CPU_DISCARD(init.rodata)                                        \
 247         MEM_DISCARD(init.data)                                          \
 248         MEM_DISCARD(init.rodata)
 249
 250 #define INIT_TEXT                                                       \
 251         *(.init.text)                                                   \
 252         DEV_DISCARD(init.text)                                          \
 253         CPU_DISCARD(init.text)                                          \
 254         MEM_DISCARD(init.text)
 255
 256 #define EXIT_DATA                                                       \
 257         *(.exit.data)                                                   \
 258         DEV_DISCARD(exit.data)                                          \
 259         DEV_DISCARD(exit.rodata)                                        \
 260         CPU_DISCARD(exit.data)                                          \
 261         CPU_DISCARD(exit.rodata)                                        \
 262         MEM_DISCARD(exit.data)                                          \
 263         MEM_DISCARD(exit.rodata)
 264
 265 #define EXIT_TEXT                                                       \
 266         *(.exit.text)                                                   \
 267         DEV_DISCARD(exit.text)                                          \
 268         CPU_DISCARD(exit.text)                                          \
 269         MEM_DISCARD(exit.text)
 270
 271                 /* DWARF debug sections.
 272                 Symbols in the DWARF debugging sections are relative to
 273                 the beginning of the section so we begin them at 0.  */
 274 #define DWARF_DEBUG                                                     \
 275                 /* DWARF 1 */                                           \
 276                 .debug          0 : { *(.debug) }                       \
 277                 .line           0 : { *(.line) }                        \
 278                 /* GNU DWARF 1 extensions */                            \
 279                 .debug_srcinfo  0 : { *(.debug_srcinfo) }               \
 280                 .debug_sfnames  0 : { *(.debug_sfnames) }               \
 281                 /* DWARF 1.1 and DWARF 2 */                             \
 282                 .debug_aranges  0 : { *(.debug_aranges) }               \
 283                 .debug_pubnames 0 : { *(.debug_pubnames) }              \
 284                 /* DWARF 2 */                                           \
 285                 .debug_info     0 : { *(.debug_info                     \
 286                                 .gnu.linkonce.wi.*) }                   \
 287                 .debug_abbrev   0 : { *(.debug_abbrev) }                \
 288                 .debug_line     0 : { *(.debug_line) }                  \
 289                 .debug_frame    0 : { *(.debug_frame) }                 \
 290                 .debug_str      0 : { *(.debug_str) }                   \
 291                 .debug_loc      0 : { *(.debug_loc) }                   \
 292                 .debug_macinfo  0 : { *(.debug_macinfo) }               \
 293                 /* SGI/MIPS DWARF 2 extensions */                       \
 294                 .debug_weaknames 0 : { *(.debug_weaknames) }            \
 295                 .debug_funcnames 0 : { *(.debug_funcnames) }            \
 296                 .debug_typenames 0 : { *(.debug_typenames) }            \
 297                 .debug_varnames  0 : { *(.debug_varnames) }             \
 298
 299                 /* Stabs debugging sections.  */
 300 #define STABS_DEBUG                                                     \
 301                 .stab 0 : { *(.stab) }                                  \
 302                 .stabstr 0 : { *(.stabstr) }                            \
 303                 .stab.excl 0 : { *(.stab.excl) }                        \
 304                 .stab.exclstr 0 : { *(.stab.exclstr) }                  \
 305                 .stab.index 0 : { *(.stab.index) }                      \
 306                 .stab.indexstr 0 : { *(.stab.indexstr) }                \
 307                 .comment 0 : { *(.comment) }
 308
 309 #define BUG_TABLE                                                       \
 310         . = ALIGN(8);                                                   \
 311         __bug_table : AT(ADDR(__bug_table) - LOAD_OFFSET) {             \
 312                 __start___bug_table = .;                                \
 313                 *(__bug_table)                                          \
 314                 __stop___bug_table = .;                                 \
 315         }
 316
 317 #define NOTES                                                           \
 318         .notes : AT(ADDR(.notes) - LOAD_OFFSET) {                       \
 319                 VMLINUX_SYMBOL(__start_notes) = .;                      \
 320                 *(.note.*)                                              \
 321                 VMLINUX_SYMBOL(__stop_notes) = .;                       \
 322         }
 323
 324 #define INITCALLS                                                       \
 325         *(.initcall0.init)                                              \
 326         *(.initcall0s.init)                                             \
 327         *(.initcall1.init)                                              \
 328         *(.initcall1s.init)                                             \
 329         *(.initcall2.init)                                              \
 330         *(.initcall2s.init)                                             \
 331         *(.initcall3.init)                                              \
 332         *(.initcall3s.init)                                             \
 333         *(.initcall4.init)                                              \
 334         *(.initcall4s.init)                                             \
 335         *(.initcall5.init)                                              \
 336         *(.initcall5s.init)                                             \
 337         *(.initcallrootfs.init)                                         \
 338         *(.initcall6.init)                                              \
 339         *(.initcall6s.init)                                             \
 340         *(.initcall7.init)                                              \
 341         *(.initcall7s.init)
 342
 343 #define PERCPU(align)                                                   \
 344         . = ALIGN(align);                                               \
 345         __per_cpu_start = .;                                            \
 346         .data.percpu  : AT(ADDR(.data.percpu) - LOAD_OFFSET) {          \
 347                 *(.data.percpu)                                         \
 348                 *(.data.percpu.shared_aligned)                          \
 349         }                                                               \
 350         __per_cpu_end = .;