include/asm-generic/vmlinux.lds.h

   1 #ifndef LOAD_OFFSET
   2 #define LOAD_OFFSET 0
   3 #endif
   4
   5 #ifndef VMLINUX_SYMBOL
   6 #define VMLINUX_SYMBOL(_sym_) _sym_
   7 #endif
   8
   9 /* Align . to a 8 byte boundary equals to maximum function alignment. */
  10 #define ALIGN_FUNCTION()  . = ALIGN(8)
  11
  12 /* The actual configuration determine if the init/exit sections
  13  * are handled as text/data or they can be discarded (which
  14  * often happens at runtime)
  15  */
  16 #ifdef CONFIG_HOTPLUG
  17 #define DEV_KEEP(sec)    *(.dev##sec)
  18 #define DEV_DISCARD(sec)
  19 #else
  20 #define DEV_KEEP(sec)
  21 #define DEV_DISCARD(sec) *(.dev##sec)
  22 #endif
  23
  24 #ifdef CONFIG_HOTPLUG_CPU
  25 #define CPU_KEEP(sec)    *(.cpu##sec)
  26 #define CPU_DISCARD(sec)
  27 #else
  28 #define CPU_KEEP(sec)
  29 #define CPU_DISCARD(sec) *(.cpu##sec)
  30 #endif
  31
  32 #if defined(CONFIG_MEMORY_HOTPLUG)
  33 #define MEM_KEEP(sec)    *(.mem##sec)
  34 #define MEM_DISCARD(sec)
  35 #else
  36 #define MEM_KEEP(sec)
  37 #define MEM_DISCARD(sec) *(.mem##sec)
  38 #endif
  39
  40
  41 /* .data section */
  42 #define DATA_DATA                                                       \
  43         *(.data)                                                        \
  44         *(.data.init.refok)                                             \
  45         *(.ref.data)                                                    \
  46         DEV_KEEP(init.data)                                             \
  47         DEV_KEEP(exit.data)                                             \
  48         CPU_KEEP(init.data)                                             \
  49         CPU_KEEP(exit.data)                                             \
  50         MEM_KEEP(init.data)                                             \
  51         MEM_KEEP(exit.data)                                             \
  52         . = ALIGN(8);                                                   \
  53         VMLINUX_SYMBOL(__start___markers) = .;                          \
  54         *(__markers)                                                    \
  55         VMLINUX_SYMBOL(__stop___markers) = .;
  56
  57 #define RO_DATA(align)                                                  \
  58         . = ALIGN((align));                                             \
  59         .rodata           : AT(ADDR(.rodata) - LOAD_OFFSET) {           \
  60                 VMLINUX_SYMBOL(__start_rodata) = .;                     \
  61                 *(.rodata) *(.rodata.*)                                 \
  62                 *(__vermagic)           /* Kernel version magic */      \
  63                 *(__markers_strings)    /* Markers: strings */          \
  64         }                                                               \
  65                                                                         \
  66         .rodata1          : AT(ADDR(.rodata1) - LOAD_OFFSET) {          \
  67                 *(.rodata1)                                             \
  68         }                                                               \
  69                                                                         \
  70         BUG_TABLE                                                       \
  71                                                                         \
  72         /* PCI quirks */                                                \
  73         .pci_fixup        : AT(ADDR(.pci_fixup) - LOAD_OFFSET) {        \
  74                 VMLINUX_SYMBOL(__start_pci_fixups_early) = .;           \
  75                 *(.pci_fixup_early)                                     \
  76                 VMLINUX_SYMBOL(__end_pci_fixups_early) = .;             \
  77                 VMLINUX_SYMBOL(__start_pci_fixups_header) = .;          \
  78                 *(.pci_fixup_header)                                    \
  79                 VMLINUX_SYMBOL(__end_pci_fixups_header) = .;            \
  80                 VMLINUX_SYMBOL(__start_pci_fixups_final) = .;           \
  81                 *(.pci_fixup_final)                                     \
  82                 VMLINUX_SYMBOL(__end_pci_fixups_final) = .;             \
  83                 VMLINUX_SYMBOL(__start_pci_fixups_enable) = .;          \
  84                 *(.pci_fixup_enable)                                    \
  85                 VMLINUX_SYMBOL(__end_pci_fixups_enable) = .;            \
  86                 VMLINUX_SYMBOL(__start_pci_fixups_resume) = .;          \
  87                 *(.pci_fixup_resume)                                    \
  88                 VMLINUX_SYMBOL(__end_pci_fixups_resume) = .;            \
  89         }                                                               \
  90                                                                         \
  91         /* RapidIO route ops */                                         \
  92         .rio_route        : AT(ADDR(.rio_route) - LOAD_OFFSET) {        \
  93                 VMLINUX_SYMBOL(__start_rio_route_ops) = .;              \
  94                 *(.rio_route_ops)                                       \
  95                 VMLINUX_SYMBOL(__end_rio_route_ops) = .;                \
  96         }                                                               \
  97                                                                         \
  98         TRACEDATA                                                       \
  99                                                                         \
 100         /* Kernel symbol table: Normal symbols */                       \
 101         __ksymtab         : AT(ADDR(__ksymtab) - LOAD_OFFSET) {         \
 102                 VMLINUX_SYMBOL(__start___ksymtab) = .;                  \
 103                 *(__ksymtab)                                            \
 104                 VMLINUX_SYMBOL(__stop___ksymtab) = .;                   \
 105         }                                                               \
 106                                                                         \
 107         /* Kernel symbol table: GPL-only symbols */                     \
 108         __ksymtab_gpl     : AT(ADDR(__ksymtab_gpl) - LOAD_OFFSET) {     \
 109                 VMLINUX_SYMBOL(__start___ksymtab_gpl) = .;              \
 110                 *(__ksymtab_gpl)                                        \
 111                 VMLINUX_SYMBOL(__stop___ksymtab_gpl) = .;               \
 112         }                                                               \
 113                                                                         \
 114         /* Kernel symbol table: Normal unused symbols */                \
 115         __ksymtab_unused  : AT(ADDR(__ksymtab_unused) - LOAD_OFFSET) {  \
 116                 VMLINUX_SYMBOL(__start___ksymtab_unused) = .;           \
 117                 *(__ksymtab_unused)                                     \
 118                 VMLINUX_SYMBOL(__stop___ksymtab_unused) = .;            \
 119         }                                                               \
 120                                                                         \
 121         /* Kernel symbol table: GPL-only unused symbols */              \
 122         __ksymtab_unused_gpl : AT(ADDR(__ksymtab_unused_gpl) - LOAD_OFFSET) { \
 123                 VMLINUX_SYMBOL(__start___ksymtab_unused_gpl) = .;       \
 124                 *(__ksymtab_unused_gpl)                                 \
 125                 VMLINUX_SYMBOL(__stop___ksymtab_unused_gpl) = .;        \
 126         }                                                               \
 127                                                                         \
 128         /* Kernel symbol table: GPL-future-only symbols */              \
 129         __ksymtab_gpl_future : AT(ADDR(__ksymtab_gpl_future) - LOAD_OFFSET) { \
 130                 VMLINUX_SYMBOL(__start___ksymtab_gpl_future) = .;       \
 131                 *(__ksymtab_gpl_future)                                 \
 132                 VMLINUX_SYMBOL(__stop___ksymtab_gpl_future) = .;        \
 133         }                                                               \
 134                                                                         \
 135         /* Kernel symbol table: Normal symbols */                       \
 136         __kcrctab         : AT(ADDR(__kcrctab) - LOAD_OFFSET) {         \
 137                 VMLINUX_SYMBOL(__start___kcrctab) = .;                  \
 138                 *(__kcrctab)                                            \
 139                 VMLINUX_SYMBOL(__stop___kcrctab) = .;                   \
 140         }                                                               \
 141                                                                         \
 142         /* Kernel symbol table: GPL-only symbols */                     \
 143         __kcrctab_gpl     : AT(ADDR(__kcrctab_gpl) - LOAD_OFFSET) {     \
 144                 VMLINUX_SYMBOL(__start___kcrctab_gpl) = .;              \
 145                 *(__kcrctab_gpl)                                        \
 146                 VMLINUX_SYMBOL(__stop___kcrctab_gpl) = .;               \
 147         }                                                               \
 148                                                                         \
 149         /* Kernel symbol table: Normal unused symbols */                \
 150         __kcrctab_unused  : AT(ADDR(__kcrctab_unused) - LOAD_OFFSET) {  \
 151                 VMLINUX_SYMBOL(__start___kcrctab_unused) = .;           \
 152                 *(__kcrctab_unused)                                     \
 153                 VMLINUX_SYMBOL(__stop___kcrctab_unused) = .;            \
 154         }                                                               \
 155                                                                         \
 156         /* Kernel symbol table: GPL-only unused symbols */              \
 157         __kcrctab_unused_gpl : AT(ADDR(__kcrctab_unused_gpl) - LOAD_OFFSET) { \
 158                 VMLINUX_SYMBOL(__start___kcrctab_unused_gpl) = .;       \
 159                 *(__kcrctab_unused_gpl)                                 \
 160                 VMLINUX_SYMBOL(__stop___kcrctab_unused_gpl) = .;        \
 161         }                                                               \
 162                                                                         \
 163         /* Kernel symbol table: GPL-future-only symbols */              \
 164         __kcrctab_gpl_future : AT(ADDR(__kcrctab_gpl_future) - LOAD_OFFSET) { \
 165                 VMLINUX_SYMBOL(__start___kcrctab_gpl_future) = .;       \
 166                 *(__kcrctab_gpl_future)                                 \
 167                 VMLINUX_SYMBOL(__stop___kcrctab_gpl_future) = .;        \
 168         }                                                               \
 169                                                                         \
 170         /* Kernel symbol table: strings */                              \
 171         __ksymtab_strings : AT(ADDR(__ksymtab_strings) - LOAD_OFFSET) { \
 172                 *(__ksymtab_strings)                                    \
 173         }                                                               \
 174                                                                         \
 175         /* __*init sections */                                          \
 176         __init_rodata : AT(ADDR(__init_rodata) - LOAD_OFFSET) {         \
 177                 *(.ref.rodata)                                          \
 178                 DEV_KEEP(init.rodata)                                   \
 179                 DEV_KEEP(exit.rodata)                                   \
 180                 CPU_KEEP(init.rodata)                                   \
 181                 CPU_KEEP(exit.rodata)                                   \
 182                 MEM_KEEP(init.rodata)                                   \
 183                 MEM_KEEP(exit.rodata)                                   \
 184         }                                                               \
 185                                                                         \
 186         /* Built-in module parameters. */                               \
 187         __param : AT(ADDR(__param) - LOAD_OFFSET) {                     \
 188                 VMLINUX_SYMBOL(__start___param) = .;                    \
 189                 *(__param)                                              \
 190                 VMLINUX_SYMBOL(__stop___param) = .;                     \
 191                 . = ALIGN((align));                                     \
 192                 VMLINUX_SYMBOL(__end_rodata) = .;                       \
 193         }                                                               \
 194         . = ALIGN((align));
 195
 196 /* RODATA provided for backward compatibility.
 197  * All archs are supposed to use RO_DATA() */
 198 #define RODATA RO_DATA(4096)
 199
 200 #define SECURITY_INIT                                                   \
 201         .security_initcall.init : AT(ADDR(.security_initcall.init) - LOAD_OFFSET) { \
 202                 VMLINUX_SYMBOL(__security_initcall_start) = .;          \
 203                 *(.security_initcall.init)                              \
 204                 VMLINUX_SYMBOL(__security_initcall_end) = .;            \
 205         }
 206
 207 /* .text section. Map to function alignment to avoid address changes
 208  * during second ld run in second ld pass when generating System.map */
 209 #define TEXT_TEXT                                                       \
 210                 ALIGN_FUNCTION();                                       \
 211                 *(.text)                                                \
 212                 *(.ref.text)                                            \
 213                 *(.text.init.refok)                                     \
 214                 *(.exit.text.refok)                                     \
 215         DEV_KEEP(init.text)                                             \
 216         DEV_KEEP(exit.text)                                             \
 217         CPU_KEEP(init.text)                                             \
 218         CPU_KEEP(exit.text)                                             \
 219         MEM_KEEP(init.text)                                             \
 220         MEM_KEEP(exit.text)
 221
 222
 223 /* sched.text is aling to function alignment to secure we have same
 224  * address even at second ld pass when generating System.map */
 225 #define SCHED_TEXT                                                      \
 226                 ALIGN_FUNCTION();                                       \
 227                 VMLINUX_SYMBOL(__sched_text_start) = .;                 \
 228                 *(.sched.text)                                          \
 229                 VMLINUX_SYMBOL(__sched_text_end) = .;
 230
 231 /* spinlock.text is aling to function alignment to secure we have same
 232  * address even at second ld pass when generating System.map */
 233 #define LOCK_TEXT                                                       \
 234                 ALIGN_FUNCTION();                                       \
 235                 VMLINUX_SYMBOL(__lock_text_start) = .;                  \
 236                 *(.spinlock.text)                                       \
 237                 VMLINUX_SYMBOL(__lock_text_end) = .;
 238
 239 #define KPROBES_TEXT                                                    \
 240                 ALIGN_FUNCTION();                                       \
 241                 VMLINUX_SYMBOL(__kprobes_text_start) = .;               \
 242                 *(.kprobes.text)                                        \
 243                 VMLINUX_SYMBOL(__kprobes_text_end) = .;
 244
 245 /* Section used for early init (in .S files) */
 246 #define HEAD_TEXT  *(.head.text)
 247
 248 /* init and exit section handling */
 249 #define INIT_DATA                                                       \
 250         *(.init.data)                                                   \
 251         DEV_DISCARD(init.data)                                          \
 252         DEV_DISCARD(init.rodata)                                        \
 253         CPU_DISCARD(init.data)                                          \
 254         CPU_DISCARD(init.rodata)                                        \
 255         MEM_DISCARD(init.data)                                          \
 256         MEM_DISCARD(init.rodata)
 257
 258 #define INIT_TEXT                                                       \
 259         *(.init.text)                                                   \
 260         DEV_DISCARD(init.text)                                          \
 261         CPU_DISCARD(init.text)                                          \
 262         MEM_DISCARD(init.text)
 263
 264 #define EXIT_DATA                                                       \
 265         *(.exit.data)                                                   \
 266         DEV_DISCARD(exit.data)                                          \
 267         DEV_DISCARD(exit.rodata)                                        \
 268         CPU_DISCARD(exit.data)                                          \
 269         CPU_DISCARD(exit.rodata)                                        \
 270         MEM_DISCARD(exit.data)                                          \
 271         MEM_DISCARD(exit.rodata)
 272
 273 #define EXIT_TEXT                                                       \
 274         *(.exit.text)                                                   \
 275         DEV_DISCARD(exit.text)                                          \
 276         CPU_DISCARD(exit.text)                                          \
 277         MEM_DISCARD(exit.text)
 278
 279                 /* DWARF debug sections.
 280                 Symbols in the DWARF debugging sections are relative to
 281                 the beginning of the section so we begin them at 0.  */
 282 #define DWARF_DEBUG                                                     \
 283                 /* DWARF 1 */                                           \
 284                 .debug          0 : { *(.debug) }                       \
 285                 .line           0 : { *(.line) }                        \
 286                 /* GNU DWARF 1 extensions */                            \
 287                 .debug_srcinfo  0 : { *(.debug_srcinfo) }               \
 288                 .debug_sfnames  0 : { *(.debug_sfnames) }               \
 289                 /* DWARF 1.1 and DWARF 2 */                             \
 290                 .debug_aranges  0 : { *(.debug_aranges) }               \
 291                 .debug_pubnames 0 : { *(.debug_pubnames) }              \
 292                 /* DWARF 2 */                                           \
 293                 .debug_info     0 : { *(.debug_info                     \
 294                                 .gnu.linkonce.wi.*) }                   \
 295                 .debug_abbrev   0 : { *(.debug_abbrev) }                \
 296                 .debug_line     0 : { *(.debug_line) }                  \
 297                 .debug_frame    0 : { *(.debug_frame) }                 \
 298                 .debug_str      0 : { *(.debug_str) }                   \
 299                 .debug_loc      0 : { *(.debug_loc) }                   \
 300                 .debug_macinfo  0 : { *(.debug_macinfo) }               \
 301                 /* SGI/MIPS DWARF 2 extensions */                       \
 302                 .debug_weaknames 0 : { *(.debug_weaknames) }            \
 303                 .debug_funcnames 0 : { *(.debug_funcnames) }            \
 304                 .debug_typenames 0 : { *(.debug_typenames) }            \
 305                 .debug_varnames  0 : { *(.debug_varnames) }             \
 306
 307                 /* Stabs debugging sections.  */
 308 #define STABS_DEBUG                                                     \
 309                 .stab 0 : { *(.stab) }                                  \
 310                 .stabstr 0 : { *(.stabstr) }                            \
 311                 .stab.excl 0 : { *(.stab.excl) }                        \
 312                 .stab.exclstr 0 : { *(.stab.exclstr) }                  \
 313                 .stab.index 0 : { *(.stab.index) }                      \
 314                 .stab.indexstr 0 : { *(.stab.indexstr) }                \
 315                 .comment 0 : { *(.comment) }
 316
 317 #ifdef CONFIG_GENERIC_BUG
 318 #define BUG_TABLE                                                       \
 319         . = ALIGN(8);                                                   \
 320         __bug_table : AT(ADDR(__bug_table) - LOAD_OFFSET) {             \
 321                 __start___bug_table = .;                                \
 322                 *(__bug_table)                                          \
 323                 __stop___bug_table = .;                                 \
 324         }
 325 #else
 326 #define BUG_TABLE
 327 #endif
 328
 329 #ifdef CONFIG_PM_TRACE
 330 #define TRACEDATA                                                       \
 331         . = ALIGN(4);                                                   \
 332         .tracedata : AT(ADDR(.tracedata) - LOAD_OFFSET) {               \
 333                 __tracedata_start = .;                                  \
 334                 *(.tracedata)                                           \
 335                 __tracedata_end = .;                                    \
 336         }
 337 #else
 338 #define TRACEDATA
 339 #endif
 340
 341 #define NOTES                                                           \
 342         .notes : AT(ADDR(.notes) - LOAD_OFFSET) {                       \
 343                 VMLINUX_SYMBOL(__start_notes) = .;                      \
 344                 *(.note.*)                                              \
 345                 VMLINUX_SYMBOL(__stop_notes) = .;                       \
 346         }
 347
 348 #define INITCALLS                                                       \
 349         *(.initcall0.init)                                              \
 350         *(.initcall0s.init)                                             \
 351         *(.initcall1.init)                                              \
 352         *(.initcall1s.init)                                             \
 353         *(.initcall2.init)                                              \
 354         *(.initcall2s.init)                                             \
 355         *(.initcall3.init)                                              \
 356         *(.initcall3s.init)                                             \
 357         *(.initcall4.init)                                              \
 358         *(.initcall4s.init)                                             \
 359         *(.initcall5.init)                                              \
 360         *(.initcall5s.init)                                             \
 361         *(.initcallrootfs.init)                                         \
 362         *(.initcall6.init)                                              \
 363         *(.initcall6s.init)                                             \
 364         *(.initcall7.init)                                              \
 365         *(.initcall7s.init)
 366
 367 #define PERCPU(align)                                                   \
 368         . = ALIGN(align);                                               \
 369         __per_cpu_start = .;                                            \
 370         .data.percpu  : AT(ADDR(.data.percpu) - LOAD_OFFSET) {          \
 371                 *(.data.percpu)                                         \
 372                 *(.data.percpu.shared_aligned)                          \
 373         }                                                               \
 374         __per_cpu_end = .;