arch/x86/kernel/suspend_asm_64.S

   1 /* Copyright 2004,2005 Pavel Machek <pavel@suse.cz>, Andi Kleen <ak@suse.de>, Rafael J. Wysocki <rjw@sisk.pl>
   2  *
   3  * Distribute under GPLv2.
   4  *
   5  * swsusp_arch_resume must not use any stack or any nonlocal variables while
   6  * copying pages:
   7  *
   8  * Its rewriting one kernel image with another. What is stack in "old"
   9  * image could very well be data page in "new" image, and overwriting
  10  * your own stack under you is bad idea.
  11  */
  12
  13         .text
  14 #include <linux/linkage.h>
  15 #include <asm/segment.h>
  16 #include <asm/page.h>
  17 #include <asm/asm-offsets.h>
  18
  19 ENTRY(swsusp_arch_suspend)
  20
  21         movq %rsp, saved_context_esp(%rip)
  22         movq %rax, saved_context_eax(%rip)
  23         movq %rbx, saved_context_ebx(%rip)
  24         movq %rcx, saved_context_ecx(%rip)
  25         movq %rdx, saved_context_edx(%rip)
  26         movq %rbp, saved_context_ebp(%rip)
  27         movq %rsi, saved_context_esi(%rip)
  28         movq %rdi, saved_context_edi(%rip)
  29         movq %r8,  saved_context_r08(%rip)
  30         movq %r9,  saved_context_r09(%rip)
  31         movq %r10, saved_context_r10(%rip)
  32         movq %r11, saved_context_r11(%rip)
  33         movq %r12, saved_context_r12(%rip)
  34         movq %r13, saved_context_r13(%rip)
  35         movq %r14, saved_context_r14(%rip)
  36         movq %r15, saved_context_r15(%rip)
  37         pushfq ; popq saved_context_eflags(%rip)
  38
  39         /* save the address of restore_registers */
  40         movq    $restore_registers, %rax
  41         movq    %rax, restore_jump_address(%rip)
  42         /* save cr3 */
  43         movq    %cr3, %rax
  44         movq    %rax, restore_cr3(%rip)
  45
  46         call swsusp_save
  47         ret
  48
  49 ENTRY(restore_image)
  50         /* switch to temporary page tables */
  51         movq    $__PAGE_OFFSET, %rdx
  52         movq    temp_level4_pgt(%rip), %rax
  53         subq    %rdx, %rax
  54         movq    %rax, %cr3
  55         /* Flush TLB */
  56         movq    mmu_cr4_features(%rip), %rax
  57         movq    %rax, %rdx
  58         andq    $~(1<<7), %rdx  # PGE
  59         movq    %rdx, %cr4;  # turn off PGE
  60         movq    %cr3, %rcx;  # flush TLB
  61         movq    %rcx, %cr3;
  62         movq    %rax, %cr4;  # turn PGE back on
  63
  64         /* prepare to jump to the image kernel */
  65         movq    restore_jump_address(%rip), %rax
  66         movq    restore_cr3(%rip), %rbx
  67
  68         /* prepare to copy image data to their original locations */
  69         movq    restore_pblist(%rip), %rdx
  70         movq    relocated_restore_code(%rip), %rcx
  71         jmpq    *%rcx
  72
  73         /* code below has been relocated to a safe page */
  74 ENTRY(core_restore_code)
  75 loop:
  76         testq   %rdx, %rdx
  77         jz      done
  78
  79         /* get addresses from the pbe and copy the page */
  80         movq    pbe_address(%rdx), %rsi
  81         movq    pbe_orig_address(%rdx), %rdi
  82         movq    $(PAGE_SIZE >> 3), %rcx
  83         rep
  84         movsq
  85
  86         /* progress to the next pbe */
  87         movq    pbe_next(%rdx), %rdx
  88         jmp     loop
  89 done:
  90         /* jump to the restore_registers address from the image header */
  91         jmpq    *%rax
  92         /*
  93          * NOTE: This assumes that the boot kernel's text mapping covers the
  94          * image kernel's page containing restore_registers and the address of
  95          * this page is the same as in the image kernel's text mapping (it
  96          * should always be true, because the text mapping is linear, starting
  97          * from 0, and is supposed to cover the entire kernel text for every
  98          * kernel).
  99          *
 100          * code below belongs to the image kernel
 101          */
 102
 103 ENTRY(restore_registers)
 104         /* go back to the original page tables */
 105         movq    %rbx, %cr3
 106
 107         /* Flush TLB, including "global" things (vmalloc) */
 108         movq    mmu_cr4_features(%rip), %rax
 109         movq    %rax, %rdx
 110         andq    $~(1<<7), %rdx;  # PGE
 111         movq    %rdx, %cr4;  # turn off PGE
 112         movq    %cr3, %rcx;  # flush TLB
 113         movq    %rcx, %cr3
 114         movq    %rax, %cr4;  # turn PGE back on
 115
 116         movq saved_context_esp(%rip), %rsp
 117         movq saved_context_ebp(%rip), %rbp
 118         /* restore GPRs (we don't restore %rax, it must be 0 anyway) */
 119         movq saved_context_ebx(%rip), %rbx
 120         movq saved_context_ecx(%rip), %rcx
 121         movq saved_context_edx(%rip), %rdx
 122         movq saved_context_esi(%rip), %rsi
 123         movq saved_context_edi(%rip), %rdi
 124         movq saved_context_r08(%rip), %r8
 125         movq saved_context_r09(%rip), %r9
 126         movq saved_context_r10(%rip), %r10
 127         movq saved_context_r11(%rip), %r11
 128         movq saved_context_r12(%rip), %r12
 129         movq saved_context_r13(%rip), %r13
 130         movq saved_context_r14(%rip), %r14
 131         movq saved_context_r15(%rip), %r15
 132         pushq saved_context_eflags(%rip) ; popfq
 133
 134         xorq    %rax, %rax
 135
 136         /* tell the hibernation core that we've just restored the memory */
 137         movq    %rax, in_suspend(%rip)
 138
 139         ret