arch/x86/kernel/entry_64.S

   1 /*
   2  *  linux/arch/x86_64/entry.S
   3  *
   4  *  Copyright (C) 1991, 1992  Linus Torvalds
   5  *  Copyright (C) 2000, 2001, 2002  Andi Kleen SuSE Labs
   6  *  Copyright (C) 2000  Pavel Machek <pavel@suse.cz>
   7  */
   8
   9 /*
  10  * entry.S contains the system-call and fault low-level handling routines.
  11  *
  12  * NOTE: This code handles signal-recognition, which happens every time
  13  * after an interrupt and after each system call.
  14  *
  15  * Normal syscalls and interrupts don't save a full stack frame, this is
  16  * only done for syscall tracing, signals or fork/exec et.al.
  17  *
  18  * A note on terminology:
  19  * - top of stack: Architecture defined interrupt frame from SS to RIP
  20  * at the top of the kernel process stack.
  21  * - partial stack frame: partially saved registers upto R11.
  22  * - full stack frame: Like partial stack frame, but all register saved.
  23  *
  24  * Some macro usage:
  25  * - CFI macros are used to generate dwarf2 unwind information for better
  26  * backtraces. They don't change any code.
  27  * - SAVE_ALL/RESTORE_ALL - Save/restore all registers
  28  * - SAVE_ARGS/RESTORE_ARGS - Save/restore registers that C functions modify.
  29  * There are unfortunately lots of special cases where some registers
  30  * not touched. The macro is a big mess that should be cleaned up.
  31  * - SAVE_REST/RESTORE_REST - Handle the registers not saved by SAVE_ARGS.
  32  * Gives a full stack frame.
  33  * - ENTRY/END Define functions in the symbol table.
  34  * - FIXUP_TOP_OF_STACK/RESTORE_TOP_OF_STACK - Fix up the hardware stack
  35  * frame that is otherwise undefined after a SYSCALL
  36  * - TRACE_IRQ_* - Trace hard interrupt state for lock debugging.
  37  * - errorentry/paranoidentry/zeroentry - Define exception entry points.
  38  */
  39
  40 #include <linux/linkage.h>
  41 #include <asm/segment.h>
  42 #include <asm/cache.h>
  43 #include <asm/errno.h>
  44 #include <asm/dwarf2.h>
  45 #include <asm/calling.h>
  46 #include <asm/asm-offsets.h>
  47 #include <asm/msr.h>
  48 #include <asm/unistd.h>
  49 #include <asm/thread_info.h>
  50 #include <asm/hw_irq.h>
  51 #include <asm/page.h>
  52 #include <asm/irqflags.h>
  53 #include <asm/paravirt.h>
  54
  55         .code64
  56
  57 #ifndef CONFIG_PREEMPT
  58 #define retint_kernel retint_restore_args
  59 #endif
  60
  61 #ifdef CONFIG_PARAVIRT
  62 ENTRY(native_irq_enable_syscall_ret)
  63         movq    %gs:pda_oldrsp,%rsp
  64         swapgs
  65         sysretq
  66 #endif /* CONFIG_PARAVIRT */
  67
  68
  69 .macro TRACE_IRQS_IRETQ offset=ARGOFFSET
  70 #ifdef CONFIG_TRACE_IRQFLAGS
  71         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
  72         jnc  1f
  73         TRACE_IRQS_ON
  74 1:
  75 #endif
  76 .endm
  77
  78 /*
  79  * C code is not supposed to know about undefined top of stack. Every time
  80  * a C function with an pt_regs argument is called from the SYSCALL based
  81  * fast path FIXUP_TOP_OF_STACK is needed.
  82  * RESTORE_TOP_OF_STACK syncs the syscall state after any possible ptregs
  83  * manipulation.
  84  */
  85
  86         /* %rsp:at FRAMEEND */
  87         .macro FIXUP_TOP_OF_STACK tmp
  88         movq    %gs:pda_oldrsp,\tmp
  89         movq    \tmp,RSP(%rsp)
  90         movq    $__USER_DS,SS(%rsp)
  91         movq    $__USER_CS,CS(%rsp)
  92         movq    $-1,RCX(%rsp)
  93         movq    R11(%rsp),\tmp  /* get eflags */
  94         movq    \tmp,EFLAGS(%rsp)
  95         .endm
  96
  97         .macro RESTORE_TOP_OF_STACK tmp,offset=0
  98         movq   RSP-\offset(%rsp),\tmp
  99         movq   \tmp,%gs:pda_oldrsp
 100         movq   EFLAGS-\offset(%rsp),\tmp
 101         movq   \tmp,R11-\offset(%rsp)
 102         .endm
 103
 104         .macro FAKE_STACK_FRAME child_rip
 105         /* push in order ss, rsp, eflags, cs, rip */
 106         xorl %eax, %eax
 107         pushq %rax /* ss */
 108         CFI_ADJUST_CFA_OFFSET   8
 109         /*CFI_REL_OFFSET        ss,0*/
 110         pushq %rax /* rsp */
 111         CFI_ADJUST_CFA_OFFSET   8
 112         CFI_REL_OFFSET  rsp,0
 113         pushq $(1<<9) /* eflags - interrupts on */
 114         CFI_ADJUST_CFA_OFFSET   8
 115         /*CFI_REL_OFFSET        rflags,0*/
 116         pushq $__KERNEL_CS /* cs */
 117         CFI_ADJUST_CFA_OFFSET   8
 118         /*CFI_REL_OFFSET        cs,0*/
 119         pushq \child_rip /* rip */
 120         CFI_ADJUST_CFA_OFFSET   8
 121         CFI_REL_OFFSET  rip,0
 122         pushq   %rax /* orig rax */
 123         CFI_ADJUST_CFA_OFFSET   8
 124         .endm
 125
 126         .macro UNFAKE_STACK_FRAME
 127         addq $8*6, %rsp
 128         CFI_ADJUST_CFA_OFFSET   -(6*8)
 129         .endm
 130
 131         .macro  CFI_DEFAULT_STACK start=1
 132         .if \start
 133         CFI_STARTPROC   simple
 134         CFI_SIGNAL_FRAME
 135         CFI_DEF_CFA     rsp,SS+8
 136         .else
 137         CFI_DEF_CFA_OFFSET SS+8
 138         .endif
 139         CFI_REL_OFFSET  r15,R15
 140         CFI_REL_OFFSET  r14,R14
 141         CFI_REL_OFFSET  r13,R13
 142         CFI_REL_OFFSET  r12,R12
 143         CFI_REL_OFFSET  rbp,RBP
 144         CFI_REL_OFFSET  rbx,RBX
 145         CFI_REL_OFFSET  r11,R11
 146         CFI_REL_OFFSET  r10,R10
 147         CFI_REL_OFFSET  r9,R9
 148         CFI_REL_OFFSET  r8,R8
 149         CFI_REL_OFFSET  rax,RAX
 150         CFI_REL_OFFSET  rcx,RCX
 151         CFI_REL_OFFSET  rdx,RDX
 152         CFI_REL_OFFSET  rsi,RSI
 153         CFI_REL_OFFSET  rdi,RDI
 154         CFI_REL_OFFSET  rip,RIP
 155         /*CFI_REL_OFFSET        cs,CS*/
 156         /*CFI_REL_OFFSET        rflags,EFLAGS*/
 157         CFI_REL_OFFSET  rsp,RSP
 158         /*CFI_REL_OFFSET        ss,SS*/
 159         .endm
 160 /*
 161  * A newly forked process directly context switches into this.
 162  */
 163 /* rdi: prev */
 164 ENTRY(ret_from_fork)
 165         CFI_DEFAULT_STACK
 166         push kernel_eflags(%rip)
 167         CFI_ADJUST_CFA_OFFSET 4
 168         popf                            # reset kernel eflags
 169         CFI_ADJUST_CFA_OFFSET -4
 170         call schedule_tail
 171         GET_THREAD_INFO(%rcx)
 172         testl $(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT),threadinfo_flags(%rcx)
 173         jnz rff_trace
 174 rff_action:
 175         RESTORE_REST
 176         testl $3,CS-ARGOFFSET(%rsp)     # from kernel_thread?
 177         je   int_ret_from_sys_call
 178         testl $_TIF_IA32,threadinfo_flags(%rcx)
 179         jnz  int_ret_from_sys_call
 180         RESTORE_TOP_OF_STACK %rdi,ARGOFFSET
 181         jmp ret_from_sys_call
 182 rff_trace:
 183         movq %rsp,%rdi
 184         call syscall_trace_leave
 185         GET_THREAD_INFO(%rcx)
 186         jmp rff_action
 187         CFI_ENDPROC
 188 END(ret_from_fork)
 189
 190 /*
 191  * System call entry. Upto 6 arguments in registers are supported.
 192  *
 193  * SYSCALL does not save anything on the stack and does not change the
 194  * stack pointer.
 195  */
 196
 197 /*
 198  * Register setup:
 199  * rax  system call number
 200  * rdi  arg0
 201  * rcx  return address for syscall/sysret, C arg3
 202  * rsi  arg1
 203  * rdx  arg2
 204  * r10  arg3    (--> moved to rcx for C)
 205  * r8   arg4
 206  * r9   arg5
 207  * r11  eflags for syscall/sysret, temporary for C
 208  * r12-r15,rbp,rbx saved by C code, not touched.
 209  *
 210  * Interrupts are off on entry.
 211  * Only called from user space.
 212  *
 213  * XXX  if we had a free scratch register we could save the RSP into the stack frame
 214  *      and report it properly in ps. Unfortunately we haven't.
 215  *
 216  * When user can change the frames always force IRET. That is because
 217  * it deals with uncanonical addresses better. SYSRET has trouble
 218  * with them due to bugs in both AMD and Intel CPUs.
 219  */
 220
 221 ENTRY(system_call)
 222         CFI_STARTPROC   simple
 223         CFI_SIGNAL_FRAME
 224         CFI_DEF_CFA     rsp,PDA_STACKOFFSET
 225         CFI_REGISTER    rip,rcx
 226         /*CFI_REGISTER  rflags,r11*/
 227         SWAPGS_UNSAFE_STACK
 228         /*
 229          * A hypervisor implementation might want to use a label
 230          * after the swapgs, so that it can do the swapgs
 231          * for the guest and jump here on syscall.
 232          */
 233 ENTRY(system_call_after_swapgs)
 234
 235         movq    %rsp,%gs:pda_oldrsp
 236         movq    %gs:pda_kernelstack,%rsp
 237         /*
 238          * No need to follow this irqs off/on section - it's straight
 239          * and short:
 240          */
 241         ENABLE_INTERRUPTS(CLBR_NONE)
 242         SAVE_ARGS 8,1
 243         movq  %rax,ORIG_RAX-ARGOFFSET(%rsp)
 244         movq  %rcx,RIP-ARGOFFSET(%rsp)
 245         CFI_REL_OFFSET rip,RIP-ARGOFFSET
 246         GET_THREAD_INFO(%rcx)
 247         testl $(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT|_TIF_SECCOMP),threadinfo_flags(%rcx)
 248         jnz tracesys
 249         cmpq $__NR_syscall_max,%rax
 250         ja badsys
 251         movq %r10,%rcx
 252         call *sys_call_table(,%rax,8)  # XXX:    rip relative
 253         movq %rax,RAX-ARGOFFSET(%rsp)
 254 /*
 255  * Syscall return path ending with SYSRET (fast path)
 256  * Has incomplete stack frame and undefined top of stack.
 257  */
 258 ret_from_sys_call:
 259         movl $_TIF_ALLWORK_MASK,%edi
 260         /* edi: flagmask */
 261 sysret_check:
 262         LOCKDEP_SYS_EXIT
 263         GET_THREAD_INFO(%rcx)
 264         DISABLE_INTERRUPTS(CLBR_NONE)
 265         TRACE_IRQS_OFF
 266         movl threadinfo_flags(%rcx),%edx
 267         andl %edi,%edx
 268         jnz  sysret_careful
 269         CFI_REMEMBER_STATE
 270         /*
 271          * sysretq will re-enable interrupts:
 272          */
 273         TRACE_IRQS_ON
 274         movq RIP-ARGOFFSET(%rsp),%rcx
 275         CFI_REGISTER    rip,rcx
 276         RESTORE_ARGS 0,-ARG_SKIP,1
 277         /*CFI_REGISTER  rflags,r11*/
 278         ENABLE_INTERRUPTS_SYSCALL_RET
 279
 280         CFI_RESTORE_STATE
 281         /* Handle reschedules */
 282         /* edx: work, edi: workmask */
 283 sysret_careful:
 284         bt $TIF_NEED_RESCHED,%edx
 285         jnc sysret_signal
 286         TRACE_IRQS_ON
 287         ENABLE_INTERRUPTS(CLBR_NONE)
 288         pushq %rdi
 289         CFI_ADJUST_CFA_OFFSET 8
 290         call schedule
 291         popq  %rdi
 292         CFI_ADJUST_CFA_OFFSET -8
 293         jmp sysret_check
 294
 295         /* Handle a signal */
 296 sysret_signal:
 297         TRACE_IRQS_ON
 298         ENABLE_INTERRUPTS(CLBR_NONE)
 299         testl $_TIF_DO_NOTIFY_MASK,%edx
 300         jz    1f
 301
 302         /* Really a signal */
 303         /* edx: work flags (arg3) */
 304         leaq do_notify_resume(%rip),%rax
 305         leaq -ARGOFFSET(%rsp),%rdi # &pt_regs -> arg1
 306         xorl %esi,%esi # oldset -> arg2
 307         call ptregscall_common
 308 1:      movl $_TIF_NEED_RESCHED,%edi
 309         /* Use IRET because user could have changed frame. This
 310            works because ptregscall_common has called FIXUP_TOP_OF_STACK. */
 311         DISABLE_INTERRUPTS(CLBR_NONE)
 312         TRACE_IRQS_OFF
 313         jmp int_with_check
 314
 315 badsys:
 316         movq $-ENOSYS,RAX-ARGOFFSET(%rsp)
 317         jmp ret_from_sys_call
 318
 319         /* Do syscall tracing */
 320 tracesys:
 321         SAVE_REST
 322         movq $-ENOSYS,RAX(%rsp) /* ptrace can change this for a bad syscall */
 323         FIXUP_TOP_OF_STACK %rdi
 324         movq %rsp,%rdi
 325         call syscall_trace_enter
 326         LOAD_ARGS ARGOFFSET  /* reload args from stack in case ptrace changed it */
 327         RESTORE_REST
 328         cmpq $__NR_syscall_max,%rax
 329         ja   int_ret_from_sys_call      /* RAX(%rsp) set to -ENOSYS above */
 330         movq %r10,%rcx  /* fixup for C */
 331         call *sys_call_table(,%rax,8)
 332         movq %rax,RAX-ARGOFFSET(%rsp)
 333         /* Use IRET because user could have changed frame */
 334
 335 /*
 336  * Syscall return path ending with IRET.
 337  * Has correct top of stack, but partial stack frame.
 338  */
 339         .globl int_ret_from_sys_call
 340 int_ret_from_sys_call:
 341         DISABLE_INTERRUPTS(CLBR_NONE)
 342         TRACE_IRQS_OFF
 343         testl $3,CS-ARGOFFSET(%rsp)
 344         je retint_restore_args
 345         movl $_TIF_ALLWORK_MASK,%edi
 346         /* edi: mask to check */
 347 int_with_check:
 348         LOCKDEP_SYS_EXIT_IRQ
 349         GET_THREAD_INFO(%rcx)
 350         movl threadinfo_flags(%rcx),%edx
 351         andl %edi,%edx
 352         jnz   int_careful
 353         andl    $~TS_COMPAT,threadinfo_status(%rcx)
 354         jmp   retint_swapgs
 355
 356         /* Either reschedule or signal or syscall exit tracking needed. */
 357         /* First do a reschedule test. */
 358         /* edx: work, edi: workmask */
 359 int_careful:
 360         bt $TIF_NEED_RESCHED,%edx
 361         jnc  int_very_careful
 362         TRACE_IRQS_ON
 363         ENABLE_INTERRUPTS(CLBR_NONE)
 364         pushq %rdi
 365         CFI_ADJUST_CFA_OFFSET 8
 366         call schedule
 367         popq %rdi
 368         CFI_ADJUST_CFA_OFFSET -8
 369         DISABLE_INTERRUPTS(CLBR_NONE)
 370         TRACE_IRQS_OFF
 371         jmp int_with_check
 372
 373         /* handle signals and tracing -- both require a full stack frame */
 374 int_very_careful:
 375         TRACE_IRQS_ON
 376         ENABLE_INTERRUPTS(CLBR_NONE)
 377         SAVE_REST
 378         /* Check for syscall exit trace */
 379         testl $(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT|_TIF_SINGLESTEP),%edx
 380         jz int_signal
 381         pushq %rdi
 382         CFI_ADJUST_CFA_OFFSET 8
 383         leaq 8(%rsp),%rdi       # &ptregs -> arg1
 384         call syscall_trace_leave
 385         popq %rdi
 386         CFI_ADJUST_CFA_OFFSET -8
 387         andl $~(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT|_TIF_SINGLESTEP),%edi
 388         jmp int_restore_rest
 389
 390 int_signal:
 391         testl $_TIF_DO_NOTIFY_MASK,%edx
 392         jz 1f
 393         movq %rsp,%rdi          # &ptregs -> arg1
 394         xorl %esi,%esi          # oldset -> arg2
 395         call do_notify_resume
 396 1:      movl $_TIF_NEED_RESCHED,%edi
 397 int_restore_rest:
 398         RESTORE_REST
 399         DISABLE_INTERRUPTS(CLBR_NONE)
 400         TRACE_IRQS_OFF
 401         jmp int_with_check
 402         CFI_ENDPROC
 403 END(system_call)
 404
 405 /*
 406  * Certain special system calls that need to save a complete full stack frame.
 407  */
 408
 409         .macro PTREGSCALL label,func,arg
 410         .globl \label
 411 \label:
 412         leaq    \func(%rip),%rax
 413         leaq    -ARGOFFSET+8(%rsp),\arg /* 8 for return address */
 414         jmp     ptregscall_common
 415 END(\label)
 416         .endm
 417
 418         CFI_STARTPROC
 419
 420         PTREGSCALL stub_clone, sys_clone, %r8
 421         PTREGSCALL stub_fork, sys_fork, %rdi
 422         PTREGSCALL stub_vfork, sys_vfork, %rdi
 423         PTREGSCALL stub_rt_sigsuspend, sys_rt_sigsuspend, %rdx
 424         PTREGSCALL stub_sigaltstack, sys_sigaltstack, %rdx
 425         PTREGSCALL stub_iopl, sys_iopl, %rsi
 426
 427 ENTRY(ptregscall_common)
 428         popq %r11
 429         CFI_ADJUST_CFA_OFFSET -8
 430         CFI_REGISTER rip, r11
 431         SAVE_REST
 432         movq %r11, %r15
 433         CFI_REGISTER rip, r15
 434         FIXUP_TOP_OF_STACK %r11
 435         call *%rax
 436         RESTORE_TOP_OF_STACK %r11
 437         movq %r15, %r11
 438         CFI_REGISTER rip, r11
 439         RESTORE_REST
 440         pushq %r11
 441         CFI_ADJUST_CFA_OFFSET 8
 442         CFI_REL_OFFSET rip, 0
 443         ret
 444         CFI_ENDPROC
 445 END(ptregscall_common)
 446
 447 ENTRY(stub_execve)
 448         CFI_STARTPROC
 449         popq %r11
 450         CFI_ADJUST_CFA_OFFSET -8
 451         CFI_REGISTER rip, r11
 452         SAVE_REST
 453         FIXUP_TOP_OF_STACK %r11
 454         movq %rsp, %rcx
 455         call sys_execve
 456         RESTORE_TOP_OF_STACK %r11
 457         movq %rax,RAX(%rsp)
 458         RESTORE_REST
 459         jmp int_ret_from_sys_call
 460         CFI_ENDPROC
 461 END(stub_execve)
 462
 463 /*
 464  * sigreturn is special because it needs to restore all registers on return.
 465  * This cannot be done with SYSRET, so use the IRET return path instead.
 466  */
 467 ENTRY(stub_rt_sigreturn)
 468         CFI_STARTPROC
 469         addq $8, %rsp
 470         CFI_ADJUST_CFA_OFFSET   -8
 471         SAVE_REST
 472         movq %rsp,%rdi
 473         FIXUP_TOP_OF_STACK %r11
 474         call sys_rt_sigreturn
 475         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
 476         RESTORE_REST
 477         jmp int_ret_from_sys_call
 478         CFI_ENDPROC
 479 END(stub_rt_sigreturn)
 480
 481 /*
 482  * initial frame state for interrupts and exceptions
 483  */
 484         .macro _frame ref
 485         CFI_STARTPROC simple
 486         CFI_SIGNAL_FRAME
 487         CFI_DEF_CFA rsp,SS+8-\ref
 488         /*CFI_REL_OFFSET ss,SS-\ref*/
 489         CFI_REL_OFFSET rsp,RSP-\ref
 490         /*CFI_REL_OFFSET rflags,EFLAGS-\ref*/
 491         /*CFI_REL_OFFSET cs,CS-\ref*/
 492         CFI_REL_OFFSET rip,RIP-\ref
 493         .endm
 494
 495 /* initial frame state for interrupts (and exceptions without error code) */
 496 #define INTR_FRAME _frame RIP
 497 /* initial frame state for exceptions with error code (and interrupts with
 498    vector already pushed) */
 499 #define XCPT_FRAME _frame ORIG_RAX
 500
 501 /*
 502  * Interrupt entry/exit.
 503  *
 504  * Interrupt entry points save only callee clobbered registers in fast path.
 505  *
 506  * Entry runs with interrupts off.
 507  */
 508
 509 /* 0(%rsp): interrupt number */
 510         .macro interrupt func
 511         cld
 512         SAVE_ARGS
 513         leaq -ARGOFFSET(%rsp),%rdi      # arg1 for handler
 514         pushq %rbp
 515         CFI_ADJUST_CFA_OFFSET   8
 516         CFI_REL_OFFSET          rbp, 0
 517         movq %rsp,%rbp
 518         CFI_DEF_CFA_REGISTER    rbp
 519         testl $3,CS(%rdi)
 520         je 1f
 521         SWAPGS
 522         /* irqcount is used to check if a CPU is already on an interrupt
 523            stack or not. While this is essentially redundant with preempt_count
 524            it is a little cheaper to use a separate counter in the PDA
 525            (short of moving irq_enter into assembly, which would be too
 526             much work) */
 527 1:      incl    %gs:pda_irqcount
 528         cmoveq %gs:pda_irqstackptr,%rsp
 529         push    %rbp                    # backlink for old unwinder
 530         /*
 531          * We entered an interrupt context - irqs are off:
 532          */
 533         TRACE_IRQS_OFF
 534         call \func
 535         .endm
 536
 537 ENTRY(common_interrupt)
 538         XCPT_FRAME
 539         interrupt do_IRQ
 540         /* 0(%rsp): oldrsp-ARGOFFSET */
 541 ret_from_intr:
 542         DISABLE_INTERRUPTS(CLBR_NONE)
 543         TRACE_IRQS_OFF
 544         decl %gs:pda_irqcount
 545         leaveq
 546         CFI_DEF_CFA_REGISTER    rsp
 547         CFI_ADJUST_CFA_OFFSET   -8
 548 exit_intr:
 549         GET_THREAD_INFO(%rcx)
 550         testl $3,CS-ARGOFFSET(%rsp)
 551         je retint_kernel
 552
 553         /* Interrupt came from user space */
 554         /*
 555          * Has a correct top of stack, but a partial stack frame
 556          * %rcx: thread info. Interrupts off.
 557          */
 558 retint_with_reschedule:
 559         movl $_TIF_WORK_MASK,%edi
 560 retint_check:
 561         LOCKDEP_SYS_EXIT_IRQ
 562         movl threadinfo_flags(%rcx),%edx
 563         andl %edi,%edx
 564         CFI_REMEMBER_STATE
 565         jnz  retint_careful
 566
 567 retint_swapgs:          /* return to user-space */
 568         /*
 569          * The iretq could re-enable interrupts:
 570          */
 571         DISABLE_INTERRUPTS(CLBR_ANY)
 572         TRACE_IRQS_IRETQ
 573         SWAPGS
 574         jmp restore_args
 575
 576 retint_restore_args:    /* return to kernel space */
 577         DISABLE_INTERRUPTS(CLBR_ANY)
 578         /*
 579          * The iretq could re-enable interrupts:
 580          */
 581         TRACE_IRQS_IRETQ
 582 restore_args:
 583         RESTORE_ARGS 0,8,0
 584
 585 irq_return:
 586         INTERRUPT_RETURN
 587
 588         .section __ex_table, "a"
 589         .quad irq_return, bad_iret
 590         .previous
 591
 592 #ifdef CONFIG_PARAVIRT
 593 ENTRY(native_iret)
 594         iretq
 595
 596         .section __ex_table,"a"
 597         .quad native_iret, bad_iret
 598         .previous
 599 #endif
 600
 601         .section .fixup,"ax"
 602 bad_iret:
 603         /*
 604          * The iret traps when the %cs or %ss being restored is bogus.
 605          * We've lost the original trap vector and error code.
 606          * #GPF is the most likely one to get for an invalid selector.
 607          * So pretend we completed the iret and took the #GPF in user mode.
 608          *
 609          * We are now running with the kernel GS after exception recovery.
 610          * But error_entry expects us to have user GS to match the user %cs,
 611          * so swap back.
 612          */
 613         pushq $0
 614
 615         SWAPGS
 616         jmp general_protection
 617
 618         .previous
 619
 620         /* edi: workmask, edx: work */
 621 retint_careful:
 622         CFI_RESTORE_STATE
 623         bt    $TIF_NEED_RESCHED,%edx
 624         jnc   retint_signal
 625         TRACE_IRQS_ON
 626         ENABLE_INTERRUPTS(CLBR_NONE)
 627         pushq %rdi
 628         CFI_ADJUST_CFA_OFFSET   8
 629         call  schedule
 630         popq %rdi
 631         CFI_ADJUST_CFA_OFFSET   -8
 632         GET_THREAD_INFO(%rcx)
 633         DISABLE_INTERRUPTS(CLBR_NONE)
 634         TRACE_IRQS_OFF
 635         jmp retint_check
 636
 637 retint_signal:
 638         testl $_TIF_DO_NOTIFY_MASK,%edx
 639         jz    retint_swapgs
 640         TRACE_IRQS_ON
 641         ENABLE_INTERRUPTS(CLBR_NONE)
 642         SAVE_REST
 643         movq $-1,ORIG_RAX(%rsp)
 644         xorl %esi,%esi          # oldset
 645         movq %rsp,%rdi          # &pt_regs
 646         call do_notify_resume
 647         RESTORE_REST
 648         DISABLE_INTERRUPTS(CLBR_NONE)
 649         TRACE_IRQS_OFF
 650         movl $_TIF_NEED_RESCHED,%edi
 651         GET_THREAD_INFO(%rcx)
 652         jmp retint_check
 653
 654 #ifdef CONFIG_PREEMPT
 655         /* Returning to kernel space. Check if we need preemption */
 656         /* rcx:  threadinfo. interrupts off. */
 657 ENTRY(retint_kernel)
 658         cmpl $0,threadinfo_preempt_count(%rcx)
 659         jnz  retint_restore_args
 660         bt  $TIF_NEED_RESCHED,threadinfo_flags(%rcx)
 661         jnc  retint_restore_args
 662         bt   $9,EFLAGS-ARGOFFSET(%rsp)  /* interrupts off? */
 663         jnc  retint_restore_args
 664         call preempt_schedule_irq
 665         jmp exit_intr
 666 #endif
 667
 668         CFI_ENDPROC
 669 END(common_interrupt)
 670
 671 /*
 672  * APIC interrupts.
 673  */
 674         .macro apicinterrupt num,func
 675         INTR_FRAME
 676         pushq $~(\num)
 677         CFI_ADJUST_CFA_OFFSET 8
 678         interrupt \func
 679         jmp ret_from_intr
 680         CFI_ENDPROC
 681         .endm
 682
 683 ENTRY(thermal_interrupt)
 684         apicinterrupt THERMAL_APIC_VECTOR,smp_thermal_interrupt
 685 END(thermal_interrupt)
 686
 687 ENTRY(threshold_interrupt)
 688         apicinterrupt THRESHOLD_APIC_VECTOR,mce_threshold_interrupt
 689 END(threshold_interrupt)
 690
 691 #ifdef CONFIG_SMP
 692 ENTRY(reschedule_interrupt)
 693         apicinterrupt RESCHEDULE_VECTOR,smp_reschedule_interrupt
 694 END(reschedule_interrupt)
 695
 696         .macro INVALIDATE_ENTRY num
 697 ENTRY(invalidate_interrupt\num)
 698         apicinterrupt INVALIDATE_TLB_VECTOR_START+\num,smp_invalidate_interrupt
 699 END(invalidate_interrupt\num)
 700         .endm
 701
 702         INVALIDATE_ENTRY 0
 703         INVALIDATE_ENTRY 1
 704         INVALIDATE_ENTRY 2
 705         INVALIDATE_ENTRY 3
 706         INVALIDATE_ENTRY 4
 707         INVALIDATE_ENTRY 5
 708         INVALIDATE_ENTRY 6
 709         INVALIDATE_ENTRY 7
 710
 711 ENTRY(call_function_interrupt)
 712         apicinterrupt CALL_FUNCTION_VECTOR,smp_call_function_interrupt
 713 END(call_function_interrupt)
 714 ENTRY(call_function_single_interrupt)
 715         apicinterrupt CALL_FUNCTION_SINGLE_VECTOR,smp_call_function_single_interrupt
 716 END(call_function_single_interrupt)
 717 ENTRY(irq_move_cleanup_interrupt)
 718         apicinterrupt IRQ_MOVE_CLEANUP_VECTOR,smp_irq_move_cleanup_interrupt
 719 END(irq_move_cleanup_interrupt)
 720 #endif
 721
 722 ENTRY(apic_timer_interrupt)
 723         apicinterrupt LOCAL_TIMER_VECTOR,smp_apic_timer_interrupt
 724 END(apic_timer_interrupt)
 725
 726 ENTRY(error_interrupt)
 727         apicinterrupt ERROR_APIC_VECTOR,smp_error_interrupt
 728 END(error_interrupt)
 729
 730 ENTRY(spurious_interrupt)
 731         apicinterrupt SPURIOUS_APIC_VECTOR,smp_spurious_interrupt
 732 END(spurious_interrupt)
 733
 734 /*
 735  * Exception entry points.
 736  */
 737         .macro zeroentry sym
 738         INTR_FRAME
 739         pushq $0        /* push error code/oldrax */
 740         CFI_ADJUST_CFA_OFFSET 8
 741         pushq %rax      /* push real oldrax to the rdi slot */
 742         CFI_ADJUST_CFA_OFFSET 8
 743         CFI_REL_OFFSET rax,0
 744         leaq  \sym(%rip),%rax
 745         jmp error_entry
 746         CFI_ENDPROC
 747         .endm
 748
 749         .macro errorentry sym
 750         XCPT_FRAME
 751         pushq %rax
 752         CFI_ADJUST_CFA_OFFSET 8
 753         CFI_REL_OFFSET rax,0
 754         leaq  \sym(%rip),%rax
 755         jmp error_entry
 756         CFI_ENDPROC
 757         .endm
 758
 759         /* error code is on the stack already */
 760         /* handle NMI like exceptions that can happen everywhere */
 761         .macro paranoidentry sym, ist=0, irqtrace=1
 762         SAVE_ALL
 763         cld
 764         movl $1,%ebx
 765         movl  $MSR_GS_BASE,%ecx
 766         rdmsr
 767         testl %edx,%edx
 768         js    1f
 769         SWAPGS
 770         xorl  %ebx,%ebx
 771 1:
 772         .if \ist
 773         movq    %gs:pda_data_offset, %rbp
 774         .endif
 775         movq %rsp,%rdi
 776         movq ORIG_RAX(%rsp),%rsi
 777         movq $-1,ORIG_RAX(%rsp)
 778         .if \ist
 779         subq    $EXCEPTION_STKSZ, per_cpu__init_tss + TSS_ist + (\ist - 1) * 8(%rbp)
 780         .endif
 781         call \sym
 782         .if \ist
 783         addq    $EXCEPTION_STKSZ, per_cpu__init_tss + TSS_ist + (\ist - 1) * 8(%rbp)
 784         .endif
 785         DISABLE_INTERRUPTS(CLBR_NONE)
 786         .if \irqtrace
 787         TRACE_IRQS_OFF
 788         .endif
 789         .endm
 790
 791         /*
 792          * "Paranoid" exit path from exception stack.
 793          * Paranoid because this is used by NMIs and cannot take
 794          * any kernel state for granted.
 795          * We don't do kernel preemption checks here, because only
 796          * NMI should be common and it does not enable IRQs and
 797          * cannot get reschedule ticks.
 798          *
 799          * "trace" is 0 for the NMI handler only, because irq-tracing
 800          * is fundamentally NMI-unsafe. (we cannot change the soft and
 801          * hard flags at once, atomically)
 802          */
 803         .macro paranoidexit trace=1
 804         /* ebx: no swapgs flag */
 805 paranoid_exit\trace:
 806         testl %ebx,%ebx                         /* swapgs needed? */
 807         jnz paranoid_restore\trace
 808         testl $3,CS(%rsp)
 809         jnz   paranoid_userspace\trace
 810 paranoid_swapgs\trace:
 811         .if \trace
 812         TRACE_IRQS_IRETQ 0
 813         .endif
 814         SWAPGS_UNSAFE_STACK
 815 paranoid_restore\trace:
 816         RESTORE_ALL 8
 817         jmp irq_return
 818 paranoid_userspace\trace:
 819         GET_THREAD_INFO(%rcx)
 820         movl threadinfo_flags(%rcx),%ebx
 821         andl $_TIF_WORK_MASK,%ebx
 822         jz paranoid_swapgs\trace
 823         movq %rsp,%rdi                  /* &pt_regs */
 824         call sync_regs
 825         movq %rax,%rsp                  /* switch stack for scheduling */
 826         testl $_TIF_NEED_RESCHED,%ebx
 827         jnz paranoid_schedule\trace
 828         movl %ebx,%edx                  /* arg3: thread flags */
 829         .if \trace
 830         TRACE_IRQS_ON
 831         .endif
 832         ENABLE_INTERRUPTS(CLBR_NONE)
 833         xorl %esi,%esi                  /* arg2: oldset */
 834         movq %rsp,%rdi                  /* arg1: &pt_regs */
 835         call do_notify_resume
 836         DISABLE_INTERRUPTS(CLBR_NONE)
 837         .if \trace
 838         TRACE_IRQS_OFF
 839         .endif
 840         jmp paranoid_userspace\trace
 841 paranoid_schedule\trace:
 842         .if \trace
 843         TRACE_IRQS_ON
 844         .endif
 845         ENABLE_INTERRUPTS(CLBR_ANY)
 846         call schedule
 847         DISABLE_INTERRUPTS(CLBR_ANY)
 848         .if \trace
 849         TRACE_IRQS_OFF
 850         .endif
 851         jmp paranoid_userspace\trace
 852         CFI_ENDPROC
 853         .endm
 854
 855 /*
 856  * Exception entry point. This expects an error code/orig_rax on the stack
 857  * and the exception handler in %rax.
 858  */
 859 KPROBE_ENTRY(error_entry)
 860         _frame RDI
 861         CFI_REL_OFFSET rax,0
 862         /* rdi slot contains rax, oldrax contains error code */
 863         cld
 864         subq  $14*8,%rsp
 865         CFI_ADJUST_CFA_OFFSET   (14*8)
 866         movq %rsi,13*8(%rsp)
 867         CFI_REL_OFFSET  rsi,RSI
 868         movq 14*8(%rsp),%rsi    /* load rax from rdi slot */
 869         CFI_REGISTER    rax,rsi
 870         movq %rdx,12*8(%rsp)
 871         CFI_REL_OFFSET  rdx,RDX
 872         movq %rcx,11*8(%rsp)
 873         CFI_REL_OFFSET  rcx,RCX
 874         movq %rsi,10*8(%rsp)    /* store rax */
 875         CFI_REL_OFFSET  rax,RAX
 876         movq %r8, 9*8(%rsp)
 877         CFI_REL_OFFSET  r8,R8
 878         movq %r9, 8*8(%rsp)
 879         CFI_REL_OFFSET  r9,R9
 880         movq %r10,7*8(%rsp)
 881         CFI_REL_OFFSET  r10,R10
 882         movq %r11,6*8(%rsp)
 883         CFI_REL_OFFSET  r11,R11
 884         movq %rbx,5*8(%rsp)
 885         CFI_REL_OFFSET  rbx,RBX
 886         movq %rbp,4*8(%rsp)
 887         CFI_REL_OFFSET  rbp,RBP
 888         movq %r12,3*8(%rsp)
 889         CFI_REL_OFFSET  r12,R12
 890         movq %r13,2*8(%rsp)
 891         CFI_REL_OFFSET  r13,R13
 892         movq %r14,1*8(%rsp)
 893         CFI_REL_OFFSET  r14,R14
 894         movq %r15,(%rsp)
 895         CFI_REL_OFFSET  r15,R15
 896         xorl %ebx,%ebx
 897         testl $3,CS(%rsp)
 898         je  error_kernelspace
 899 error_swapgs:
 900         SWAPGS
 901 error_sti:
 902         movq %rdi,RDI(%rsp)
 903         CFI_REL_OFFSET  rdi,RDI
 904         movq %rsp,%rdi
 905         movq ORIG_RAX(%rsp),%rsi        /* get error code */
 906         movq $-1,ORIG_RAX(%rsp)
 907         call *%rax
 908         /* ebx: no swapgs flag (1: don't need swapgs, 0: need it) */
 909 error_exit:
 910         movl %ebx,%eax
 911         RESTORE_REST
 912         DISABLE_INTERRUPTS(CLBR_NONE)
 913         TRACE_IRQS_OFF
 914         GET_THREAD_INFO(%rcx)
 915         testl %eax,%eax
 916         jne  retint_kernel
 917         LOCKDEP_SYS_EXIT_IRQ
 918         movl  threadinfo_flags(%rcx),%edx
 919         movl  $_TIF_WORK_MASK,%edi
 920         andl  %edi,%edx
 921         jnz  retint_careful
 922         jmp retint_swapgs
 923         CFI_ENDPROC
 924
 925 error_kernelspace:
 926         incl %ebx
 927        /* There are two places in the kernel that can potentially fault with
 928           usergs. Handle them here. The exception handlers after
 929            iret run with kernel gs again, so don't set the user space flag.
 930            B stepping K8s sometimes report an truncated RIP for IRET
 931            exceptions returning to compat mode. Check for these here too. */
 932         leaq irq_return(%rip),%rbp
 933         cmpq %rbp,RIP(%rsp)
 934         je   error_swapgs
 935         movl %ebp,%ebp  /* zero extend */
 936         cmpq %rbp,RIP(%rsp)
 937         je   error_swapgs
 938         cmpq $gs_change,RIP(%rsp)
 939         je   error_swapgs
 940         jmp  error_sti
 941 KPROBE_END(error_entry)
 942
 943        /* Reload gs selector with exception handling */
 944        /* edi:  new selector */
 945 ENTRY(load_gs_index)
 946         CFI_STARTPROC
 947         pushf
 948         CFI_ADJUST_CFA_OFFSET 8
 949         DISABLE_INTERRUPTS(CLBR_ANY | ~(CLBR_RDI))
 950         SWAPGS
 951 gs_change:
 952         movl %edi,%gs
 953 2:      mfence          /* workaround */
 954         SWAPGS
 955         popf
 956         CFI_ADJUST_CFA_OFFSET -8
 957         ret
 958         CFI_ENDPROC
 959 ENDPROC(load_gs_index)
 960
 961         .section __ex_table,"a"
 962         .align 8
 963         .quad gs_change,bad_gs
 964         .previous
 965         .section .fixup,"ax"
 966         /* running with kernelgs */
 967 bad_gs:
 968         SWAPGS                  /* switch back to user gs */
 969         xorl %eax,%eax
 970         movl %eax,%gs
 971         jmp  2b
 972         .previous
 973
 974 /*
 975  * Create a kernel thread.
 976  *
 977  * C extern interface:
 978  *      extern long kernel_thread(int (*fn)(void *), void * arg, unsigned long flags)
 979  *
 980  * asm input arguments:
 981  *      rdi: fn, rsi: arg, rdx: flags
 982  */
 983 ENTRY(kernel_thread)
 984         CFI_STARTPROC
 985         FAKE_STACK_FRAME $child_rip
 986         SAVE_ALL
 987
 988         # rdi: flags, rsi: usp, rdx: will be &pt_regs
 989         movq %rdx,%rdi
 990         orq  kernel_thread_flags(%rip),%rdi
 991         movq $-1, %rsi
 992         movq %rsp, %rdx
 993
 994         xorl %r8d,%r8d
 995         xorl %r9d,%r9d
 996
 997         # clone now
 998         call do_fork
 999         movq %rax,RAX(%rsp)
1000         xorl %edi,%edi
1001
1002         /*
1003          * It isn't worth to check for reschedule here,
1004          * so internally to the x86_64 port you can rely on kernel_thread()
1005          * not to reschedule the child before returning, this avoids the need
1006          * of hacks for example to fork off the per-CPU idle tasks.
1007          * [Hopefully no generic code relies on the reschedule -AK]
1008          */
1009         RESTORE_ALL
1010         UNFAKE_STACK_FRAME
1011         ret
1012         CFI_ENDPROC
1013 ENDPROC(kernel_thread)
1014
1015 child_rip:
1016         pushq $0                # fake return address
1017         CFI_STARTPROC
1018         /*
1019          * Here we are in the child and the registers are set as they were
1020          * at kernel_thread() invocation in the parent.
1021          */
1022         movq %rdi, %rax
1023         movq %rsi, %rdi
1024         call *%rax
1025         # exit
1026         mov %eax, %edi
1027         call do_exit
1028         CFI_ENDPROC
1029 ENDPROC(child_rip)
1030
1031 /*
1032  * execve(). This function needs to use IRET, not SYSRET, to set up all state properly.
1033  *
1034  * C extern interface:
1035  *       extern long execve(char *name, char **argv, char **envp)
1036  *
1037  * asm input arguments:
1038  *      rdi: name, rsi: argv, rdx: envp
1039  *
1040  * We want to fallback into:
1041  *      extern long sys_execve(char *name, char **argv,char **envp, struct pt_regs *regs)
1042  *
1043  * do_sys_execve asm fallback arguments:
1044  *      rdi: name, rsi: argv, rdx: envp, rcx: fake frame on the stack
1045  */
1046 ENTRY(kernel_execve)
1047         CFI_STARTPROC
1048         FAKE_STACK_FRAME $0
1049         SAVE_ALL
1050         movq %rsp,%rcx
1051         call sys_execve
1052         movq %rax, RAX(%rsp)
1053         RESTORE_REST
1054         testq %rax,%rax
1055         je int_ret_from_sys_call
1056         RESTORE_ARGS
1057         UNFAKE_STACK_FRAME
1058         ret
1059         CFI_ENDPROC
1060 ENDPROC(kernel_execve)
1061
1062 KPROBE_ENTRY(page_fault)
1063         errorentry do_page_fault
1064 KPROBE_END(page_fault)
1065
1066 ENTRY(coprocessor_error)
1067         zeroentry do_coprocessor_error
1068 END(coprocessor_error)
1069
1070 ENTRY(simd_coprocessor_error)
1071         zeroentry do_simd_coprocessor_error
1072 END(simd_coprocessor_error)
1073
1074 ENTRY(device_not_available)
1075         zeroentry math_state_restore
1076 END(device_not_available)
1077
1078         /* runs on exception stack */
1079 KPROBE_ENTRY(debug)
1080         INTR_FRAME
1081         pushq $0
1082         CFI_ADJUST_CFA_OFFSET 8
1083         paranoidentry do_debug, DEBUG_STACK
1084         paranoidexit
1085 KPROBE_END(debug)
1086
1087         /* runs on exception stack */
1088 KPROBE_ENTRY(nmi)
1089         INTR_FRAME
1090         pushq $-1
1091         CFI_ADJUST_CFA_OFFSET 8
1092         paranoidentry do_nmi, 0, 0
1093 #ifdef CONFIG_TRACE_IRQFLAGS
1094         paranoidexit 0
1095 #else
1096         jmp paranoid_exit1
1097         CFI_ENDPROC
1098 #endif
1099 KPROBE_END(nmi)
1100
1101 KPROBE_ENTRY(int3)
1102         INTR_FRAME
1103         pushq $0
1104         CFI_ADJUST_CFA_OFFSET 8
1105         paranoidentry do_int3, DEBUG_STACK
1106         jmp paranoid_exit1
1107         CFI_ENDPROC
1108 KPROBE_END(int3)
1109
1110 ENTRY(overflow)
1111         zeroentry do_overflow
1112 END(overflow)
1113
1114 ENTRY(bounds)
1115         zeroentry do_bounds
1116 END(bounds)
1117
1118 ENTRY(invalid_op)
1119         zeroentry do_invalid_op
1120 END(invalid_op)
1121
1122 ENTRY(coprocessor_segment_overrun)
1123         zeroentry do_coprocessor_segment_overrun
1124 END(coprocessor_segment_overrun)
1125
1126 ENTRY(reserved)
1127         zeroentry do_reserved
1128 END(reserved)
1129
1130         /* runs on exception stack */
1131 ENTRY(double_fault)
1132         XCPT_FRAME
1133         paranoidentry do_double_fault
1134         jmp paranoid_exit1
1135         CFI_ENDPROC
1136 END(double_fault)
1137
1138 ENTRY(invalid_TSS)
1139         errorentry do_invalid_TSS
1140 END(invalid_TSS)
1141
1142 ENTRY(segment_not_present)
1143         errorentry do_segment_not_present
1144 END(segment_not_present)
1145
1146         /* runs on exception stack */
1147 ENTRY(stack_segment)
1148         XCPT_FRAME
1149         paranoidentry do_stack_segment
1150         jmp paranoid_exit1
1151         CFI_ENDPROC
1152 END(stack_segment)
1153
1154 KPROBE_ENTRY(general_protection)
1155         errorentry do_general_protection
1156 KPROBE_END(general_protection)
1157
1158 ENTRY(alignment_check)
1159         errorentry do_alignment_check
1160 END(alignment_check)
1161
1162 ENTRY(divide_error)
1163         zeroentry do_divide_error
1164 END(divide_error)
1165
1166 ENTRY(spurious_interrupt_bug)
1167         zeroentry do_spurious_interrupt_bug
1168 END(spurious_interrupt_bug)
1169
1170 #ifdef CONFIG_X86_MCE
1171         /* runs on exception stack */
1172 ENTRY(machine_check)
1173         INTR_FRAME
1174         pushq $0
1175         CFI_ADJUST_CFA_OFFSET 8
1176         paranoidentry do_machine_check
1177         jmp paranoid_exit1
1178         CFI_ENDPROC
1179 END(machine_check)
1180 #endif
1181
1182 /* Call softirq on interrupt stack. Interrupts are off. */
1183 ENTRY(call_softirq)
1184         CFI_STARTPROC
1185         push %rbp
1186         CFI_ADJUST_CFA_OFFSET   8
1187         CFI_REL_OFFSET rbp,0
1188         mov  %rsp,%rbp
1189         CFI_DEF_CFA_REGISTER rbp
1190         incl %gs:pda_irqcount
1191         cmove %gs:pda_irqstackptr,%rsp
1192         push  %rbp                      # backlink for old unwinder
1193         call __do_softirq
1194         leaveq
1195         CFI_DEF_CFA_REGISTER    rsp
1196         CFI_ADJUST_CFA_OFFSET   -8
1197         decl %gs:pda_irqcount
1198         ret
1199         CFI_ENDPROC
1200 ENDPROC(call_softirq)
1201
1202 KPROBE_ENTRY(ignore_sysret)
1203         CFI_STARTPROC
1204         mov $-ENOSYS,%eax
1205         sysret
1206         CFI_ENDPROC
1207 ENDPROC(ignore_sysret)