arch/s390/kernel/entry64.S

   1 /*
   2  *  arch/s390/kernel/entry64.S
   3  *    S390 low-level entry points.
   4  *
   5  *    Copyright (C) IBM Corp. 1999,2006
   6  *    Author(s): Martin Schwidefsky (schwidefsky@de.ibm.com),
   7  *               Hartmut Penner (hp@de.ibm.com),
   8  *               Denis Joseph Barrow (djbarrow@de.ibm.com,barrow_dj@yahoo.com),
   9  *               Heiko Carstens <heiko.carstens@de.ibm.com>
  10  */
  11
  12 #include <linux/sys.h>
  13 #include <linux/linkage.h>
  14 #include <linux/init.h>
  15 #include <asm/cache.h>
  16 #include <asm/lowcore.h>
  17 #include <asm/errno.h>
  18 #include <asm/ptrace.h>
  19 #include <asm/thread_info.h>
  20 #include <asm/asm-offsets.h>
  21 #include <asm/unistd.h>
  22 #include <asm/page.h>
  23
  24 /*
  25  * Stack layout for the system_call stack entry.
  26  * The first few entries are identical to the user_regs_struct.
  27  */
  28 SP_PTREGS    =  STACK_FRAME_OVERHEAD
  29 SP_ARGS      =  STACK_FRAME_OVERHEAD + __PT_ARGS
  30 SP_PSW       =  STACK_FRAME_OVERHEAD + __PT_PSW
  31 SP_R0        =  STACK_FRAME_OVERHEAD + __PT_GPRS
  32 SP_R1        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 8
  33 SP_R2        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 16
  34 SP_R3        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 24
  35 SP_R4        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 32
  36 SP_R5        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 40
  37 SP_R6        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 48
  38 SP_R7        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 56
  39 SP_R8        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 64
  40 SP_R9        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 72
  41 SP_R10       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 80
  42 SP_R11       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 88
  43 SP_R12       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 96
  44 SP_R13       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 104
  45 SP_R14       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 112
  46 SP_R15       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 120
  47 SP_ORIG_R2   =  STACK_FRAME_OVERHEAD + __PT_ORIG_GPR2
  48 SP_ILC       =  STACK_FRAME_OVERHEAD + __PT_ILC
  49 SP_SVCNR      = STACK_FRAME_OVERHEAD + __PT_SVCNR
  50 SP_SIZE      =  STACK_FRAME_OVERHEAD + __PT_SIZE
  51
  52 STACK_SHIFT = PAGE_SHIFT + THREAD_ORDER
  53 STACK_SIZE  = 1 << STACK_SHIFT
  54
  55 _TIF_WORK_SVC = (_TIF_SIGPENDING | _TIF_NOTIFY_RESUME | _TIF_NEED_RESCHED | \
  56                  _TIF_MCCK_PENDING | _TIF_RESTART_SVC | _TIF_SINGLE_STEP )
  57 _TIF_WORK_INT = (_TIF_SIGPENDING | _TIF_NOTIFY_RESUME | _TIF_NEED_RESCHED | \
  58                  _TIF_MCCK_PENDING)
  59
  60 #define BASED(name) name-system_call(%r13)
  61
  62 #ifdef CONFIG_TRACE_IRQFLAGS
  63         .macro  TRACE_IRQS_ON
  64          basr   %r2,%r0
  65          brasl  %r14,trace_hardirqs_on_caller
  66         .endm
  67
  68         .macro  TRACE_IRQS_OFF
  69          basr   %r2,%r0
  70          brasl  %r14,trace_hardirqs_off_caller
  71         .endm
  72
  73         .macro TRACE_IRQS_CHECK
  74         basr    %r2,%r0
  75         tm      SP_PSW(%r15),0x03       # irqs enabled?
  76         jz      0f
  77         brasl   %r14,trace_hardirqs_on_caller
  78         j       1f
  79 0:      brasl   %r14,trace_hardirqs_off_caller
  80 1:
  81         .endm
  82 #else
  83 #define TRACE_IRQS_ON
  84 #define TRACE_IRQS_OFF
  85 #define TRACE_IRQS_CHECK
  86 #endif
  87
  88 #ifdef CONFIG_LOCKDEP
  89         .macro  LOCKDEP_SYS_EXIT
  90         tm      SP_PSW+1(%r15),0x01     # returning to user ?
  91         jz      0f
  92         brasl   %r14,lockdep_sys_exit
  93 0:
  94         .endm
  95 #else
  96 #define LOCKDEP_SYS_EXIT
  97 #endif
  98
  99         .macro  STORE_TIMER lc_offset
 100 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
 101         stpt    \lc_offset
 102 #endif
 103         .endm
 104
 105 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
 106         .macro  UPDATE_VTIME lc_from,lc_to,lc_sum
 107         lg      %r10,\lc_from
 108         slg     %r10,\lc_to
 109         alg     %r10,\lc_sum
 110         stg     %r10,\lc_sum
 111         .endm
 112 #endif
 113
 114 /*
 115  * Register usage in interrupt handlers:
 116  *    R9  - pointer to current task structure
 117  *    R13 - pointer to literal pool
 118  *    R14 - return register for function calls
 119  *    R15 - kernel stack pointer
 120  */
 121
 122         .macro  SAVE_ALL_BASE savearea
 123         stmg    %r12,%r15,\savearea
 124         larl    %r13,system_call
 125         .endm
 126
 127         .macro  SAVE_ALL_SVC psworg,savearea
 128         la      %r12,\psworg
 129         lg      %r15,__LC_KERNEL_STACK  # problem state -> load ksp
 130         .endm
 131
 132         .macro  SAVE_ALL_SYNC psworg,savearea
 133         la      %r12,\psworg
 134         tm      \psworg+1,0x01          # test problem state bit
 135         jz      2f                      # skip stack setup save
 136         lg      %r15,__LC_KERNEL_STACK  # problem state -> load ksp
 137 #ifdef CONFIG_CHECK_STACK
 138         j       3f
 139 2:      tml     %r15,STACK_SIZE - CONFIG_STACK_GUARD
 140         jz      stack_overflow
 141 3:
 142 #endif
 143 2:
 144         .endm
 145
 146         .macro  SAVE_ALL_ASYNC psworg,savearea
 147         la      %r12,\psworg
 148         tm      \psworg+1,0x01          # test problem state bit
 149         jnz     1f                      # from user -> load kernel stack
 150         clc     \psworg+8(8),BASED(.Lcritical_end)
 151         jhe     0f
 152         clc     \psworg+8(8),BASED(.Lcritical_start)
 153         jl      0f
 154         brasl   %r14,cleanup_critical
 155         tm      1(%r12),0x01            # retest problem state after cleanup
 156         jnz     1f
 157 0:      lg      %r14,__LC_ASYNC_STACK   # are we already on the async. stack ?
 158         slgr    %r14,%r15
 159         srag    %r14,%r14,STACK_SHIFT
 160         jz      2f
 161 1:      lg      %r15,__LC_ASYNC_STACK   # load async stack
 162 #ifdef CONFIG_CHECK_STACK
 163         j       3f
 164 2:      tml     %r15,STACK_SIZE - CONFIG_STACK_GUARD
 165         jz      stack_overflow
 166 3:
 167 #endif
 168 2:
 169         .endm
 170
 171         .macro  CREATE_STACK_FRAME psworg,savearea
 172         aghi    %r15,-SP_SIZE           # make room for registers & psw
 173         mvc     SP_PSW(16,%r15),0(%r12) # move user PSW to stack
 174         stg     %r2,SP_ORIG_R2(%r15)    # store original content of gpr 2
 175         icm     %r12,3,__LC_SVC_ILC
 176         stmg    %r0,%r11,SP_R0(%r15)    # store gprs %r0-%r11 to kernel stack
 177         st      %r12,SP_SVCNR(%r15)
 178         mvc     SP_R12(32,%r15),\savearea # move %r12-%r15 to stack
 179         la      %r12,0
 180         stg     %r12,__SF_BACKCHAIN(%r15)
 181         .endm
 182
 183         .macro  RESTORE_ALL psworg,sync
 184         mvc     \psworg(16),SP_PSW(%r15) # move user PSW to lowcore
 185         .if !\sync
 186         ni      \psworg+1,0xfd          # clear wait state bit
 187         .endif
 188         lmg     %r0,%r15,SP_R0(%r15)    # load gprs 0-15 of user
 189         STORE_TIMER __LC_EXIT_TIMER
 190         lpswe   \psworg                 # back to caller
 191         .endm
 192
 193 /*
 194  * Scheduler resume function, called by switch_to
 195  *  gpr2 = (task_struct *) prev
 196  *  gpr3 = (task_struct *) next
 197  * Returns:
 198  *  gpr2 = prev
 199  */
 200         .globl  __switch_to
 201 __switch_to:
 202         tm      __THREAD_per+4(%r3),0xe8 # is the new process using per ?
 203         jz      __switch_to_noper               # if not we're fine
 204         stctg   %c9,%c11,__SF_EMPTY(%r15)# We are using per stuff
 205         clc     __THREAD_per(24,%r3),__SF_EMPTY(%r15)
 206         je      __switch_to_noper            # we got away without bashing TLB's
 207         lctlg   %c9,%c11,__THREAD_per(%r3)      # Nope we didn't
 208 __switch_to_noper:
 209         lg      %r4,__THREAD_info(%r2)              # get thread_info of prev
 210         tm      __TI_flags+7(%r4),_TIF_MCCK_PENDING # machine check pending?
 211         jz      __switch_to_no_mcck
 212         ni      __TI_flags+7(%r4),255-_TIF_MCCK_PENDING # clear flag in prev
 213         lg      %r4,__THREAD_info(%r3)              # get thread_info of next
 214         oi      __TI_flags+7(%r4),_TIF_MCCK_PENDING # set it in next
 215 __switch_to_no_mcck:
 216         stmg    %r6,%r15,__SF_GPRS(%r15)# store __switch_to registers of prev task
 217         stg     %r15,__THREAD_ksp(%r2)  # store kernel stack to prev->tss.ksp
 218         lg      %r15,__THREAD_ksp(%r3)  # load kernel stack from next->tss.ksp
 219         lmg     %r6,%r15,__SF_GPRS(%r15)# load __switch_to registers of next task
 220         stg     %r3,__LC_CURRENT        # __LC_CURRENT = current task struct
 221         lctl    %c4,%c4,__TASK_pid(%r3) # load pid to control reg. 4
 222         lg      %r3,__THREAD_info(%r3)  # load thread_info from task struct
 223         stg     %r3,__LC_THREAD_INFO
 224         aghi    %r3,STACK_SIZE
 225         stg     %r3,__LC_KERNEL_STACK   # __LC_KERNEL_STACK = new kernel stack
 226         br      %r14
 227
 228 __critical_start:
 229 /*
 230  * SVC interrupt handler routine. System calls are synchronous events and
 231  * are executed with interrupts enabled.
 232  */
 233
 234         .globl  system_call
 235 system_call:
 236         STORE_TIMER __LC_SYNC_ENTER_TIMER
 237 sysc_saveall:
 238         SAVE_ALL_BASE __LC_SAVE_AREA
 239         SAVE_ALL_SVC __LC_SVC_OLD_PSW,__LC_SAVE_AREA
 240         CREATE_STACK_FRAME __LC_SVC_OLD_PSW,__LC_SAVE_AREA
 241         llgh    %r7,__LC_SVC_INT_CODE   # get svc number from lowcore
 242 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
 243 sysc_vtime:
 244         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
 245 sysc_stime:
 246         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 247 sysc_update:
 248         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
 249 #endif
 250 sysc_do_svc:
 251         lg      %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
 252         ltgr    %r7,%r7         # test for svc 0
 253         jnz     sysc_nr_ok
 254         # svc 0: system call number in %r1
 255         cl      %r1,BASED(.Lnr_syscalls)
 256         jnl     sysc_nr_ok
 257         lgfr    %r7,%r1         # clear high word in r1
 258 sysc_nr_ok:
 259         mvc     SP_ARGS(8,%r15),SP_R7(%r15)
 260 sysc_do_restart:
 261         sth     %r7,SP_SVCNR(%r15)
 262         sllg    %r7,%r7,2       # svc number * 4
 263         larl    %r10,sys_call_table
 264 #ifdef CONFIG_COMPAT
 265         tm      __TI_flags+5(%r9),(_TIF_31BIT>>16)  # running in 31 bit mode ?
 266         jno     sysc_noemu
 267         larl    %r10,sys_call_table_emu  # use 31 bit emulation system calls
 268 sysc_noemu:
 269 #endif
 270         tm      __TI_flags+7(%r9),(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT)
 271         lgf     %r8,0(%r7,%r10) # load address of system call routine
 272         jnz     sysc_tracesys
 273         basr    %r14,%r8        # call sys_xxxx
 274         stg     %r2,SP_R2(%r15) # store return value (change R2 on stack)
 275
 276 sysc_return:
 277         tm      __TI_flags+7(%r9),_TIF_WORK_SVC
 278         jnz     sysc_work       # there is work to do (signals etc.)
 279 sysc_restore:
 280 #ifdef CONFIG_TRACE_IRQFLAGS
 281         larl    %r1,sysc_restore_trace_psw
 282         lpswe   0(%r1)
 283 sysc_restore_trace:
 284         TRACE_IRQS_CHECK
 285         LOCKDEP_SYS_EXIT
 286 #endif
 287 sysc_leave:
 288         RESTORE_ALL __LC_RETURN_PSW,1
 289 sysc_done:
 290
 291 #ifdef CONFIG_TRACE_IRQFLAGS
 292         .align  8
 293         .globl sysc_restore_trace_psw
 294 sysc_restore_trace_psw:
 295         .quad   0, sysc_restore_trace
 296 #endif
 297
 298 #
 299 # recheck if there is more work to do
 300 #
 301 sysc_work_loop:
 302         tm      __TI_flags+7(%r9),_TIF_WORK_SVC
 303         jz      sysc_restore      # there is no work to do
 304 #
 305 # One of the work bits is on. Find out which one.
 306 #
 307 sysc_work:
 308         tm      SP_PSW+1(%r15),0x01     # returning to user ?
 309         jno     sysc_restore
 310         tm      __TI_flags+7(%r9),_TIF_MCCK_PENDING
 311         jo      sysc_mcck_pending
 312         tm      __TI_flags+7(%r9),_TIF_NEED_RESCHED
 313         jo      sysc_reschedule
 314         tm      __TI_flags+7(%r9),_TIF_SIGPENDING
 315         jnz     sysc_sigpending
 316         tm      __TI_flags+7(%r9),_TIF_NOTIFY_RESUME
 317         jnz     sysc_notify_resume
 318         tm      __TI_flags+7(%r9),_TIF_RESTART_SVC
 319         jo      sysc_restart
 320         tm      __TI_flags+7(%r9),_TIF_SINGLE_STEP
 321         jo      sysc_singlestep
 322         j       sysc_restore
 323 sysc_work_done:
 324
 325 #
 326 # _TIF_NEED_RESCHED is set, call schedule
 327 #
 328 sysc_reschedule:
 329         larl    %r14,sysc_work_loop
 330         jg      schedule        # return point is sysc_return
 331
 332 #
 333 # _TIF_MCCK_PENDING is set, call handler
 334 #
 335 sysc_mcck_pending:
 336         larl    %r14,sysc_work_loop
 337         jg      s390_handle_mcck        # TIF bit will be cleared by handler
 338
 339 #
 340 # _TIF_SIGPENDING is set, call do_signal
 341 #
 342 sysc_sigpending:
 343         ni      __TI_flags+7(%r9),255-_TIF_SINGLE_STEP # clear TIF_SINGLE_STEP
 344         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 345         brasl   %r14,do_signal          # call do_signal
 346         tm      __TI_flags+7(%r9),_TIF_RESTART_SVC
 347         jo      sysc_restart
 348         tm      __TI_flags+7(%r9),_TIF_SINGLE_STEP
 349         jo      sysc_singlestep
 350         j       sysc_work_loop
 351
 352 #
 353 # _TIF_NOTIFY_RESUME is set, call do_notify_resume
 354 #
 355 sysc_notify_resume:
 356         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 357         larl    %r14,sysc_work_loop
 358         jg      do_notify_resume        # call do_notify_resume
 359
 360 #
 361 # _TIF_RESTART_SVC is set, set up registers and restart svc
 362 #
 363 sysc_restart:
 364         ni      __TI_flags+7(%r9),255-_TIF_RESTART_SVC # clear TIF_RESTART_SVC
 365         lg      %r7,SP_R2(%r15)         # load new svc number
 366         mvc     SP_R2(8,%r15),SP_ORIG_R2(%r15) # restore first argument
 367         lmg     %r2,%r6,SP_R2(%r15)     # load svc arguments
 368         j       sysc_do_restart         # restart svc
 369
 370 #
 371 # _TIF_SINGLE_STEP is set, call do_single_step
 372 #
 373 sysc_singlestep:
 374         ni      __TI_flags+7(%r9),255-_TIF_SINGLE_STEP  # clear TIF_SINGLE_STEP
 375         xc      SP_SVCNR(2,%r15),SP_SVCNR(%r15)         # clear svc number
 376         la      %r2,SP_PTREGS(%r15)     # address of register-save area
 377         larl    %r14,sysc_return        # load adr. of system return
 378         jg      do_single_step          # branch to do_sigtrap
 379
 380 #
 381 # call tracehook_report_syscall_entry/tracehook_report_syscall_exit before
 382 # and after the system call
 383 #
 384 sysc_tracesys:
 385         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 386         la      %r3,0
 387         srl     %r7,2
 388         stg     %r7,SP_R2(%r15)
 389         brasl   %r14,do_syscall_trace_enter
 390         lghi    %r0,NR_syscalls
 391         clgr    %r0,%r2
 392         jnh     sysc_tracenogo
 393         sllg    %r7,%r2,2               # svc number *4
 394         lgf     %r8,0(%r7,%r10)
 395 sysc_tracego:
 396         lmg     %r3,%r6,SP_R3(%r15)
 397         lg      %r2,SP_ORIG_R2(%r15)
 398         basr    %r14,%r8                # call sys_xxx
 399         stg     %r2,SP_R2(%r15)         # store return value
 400 sysc_tracenogo:
 401         tm      __TI_flags+7(%r9),(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT)
 402         jz      sysc_return
 403         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 404         larl    %r14,sysc_return        # return point is sysc_return
 405         jg      do_syscall_trace_exit
 406
 407 #
 408 # a new process exits the kernel with ret_from_fork
 409 #
 410         .globl  ret_from_fork
 411 ret_from_fork:
 412         lg      %r13,__LC_SVC_NEW_PSW+8
 413         lg      %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
 414         tm      SP_PSW+1(%r15),0x01     # forking a kernel thread ?
 415         jo      0f
 416         stg     %r15,SP_R15(%r15)       # store stack pointer for new kthread
 417 0:      brasl   %r14,schedule_tail
 418         TRACE_IRQS_ON
 419         stosm   24(%r15),0x03           # reenable interrupts
 420         j       sysc_return
 421
 422 #
 423 # kernel_execve function needs to deal with pt_regs that is not
 424 # at the usual place
 425 #
 426         .globl  kernel_execve
 427 kernel_execve:
 428         stmg    %r12,%r15,96(%r15)
 429         lgr     %r14,%r15
 430         aghi    %r15,-SP_SIZE
 431         stg     %r14,__SF_BACKCHAIN(%r15)
 432         la      %r12,SP_PTREGS(%r15)
 433         xc      0(__PT_SIZE,%r12),0(%r12)
 434         lgr     %r5,%r12
 435         brasl   %r14,do_execve
 436         ltgfr   %r2,%r2
 437         je      0f
 438         aghi    %r15,SP_SIZE
 439         lmg     %r12,%r15,96(%r15)
 440         br      %r14
 441         # execve succeeded.
 442 0:      stnsm   __SF_EMPTY(%r15),0xfc   # disable interrupts
 443         lg      %r15,__LC_KERNEL_STACK  # load ksp
 444         aghi    %r15,-SP_SIZE           # make room for registers & psw
 445         lg      %r13,__LC_SVC_NEW_PSW+8
 446         lg      %r9,__LC_THREAD_INFO
 447         mvc     SP_PTREGS(__PT_SIZE,%r15),0(%r12)       # copy pt_regs
 448         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
 449         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
 450         brasl   %r14,execve_tail
 451         j       sysc_return
 452
 453 /*
 454  * Program check handler routine
 455  */
 456
 457         .globl  pgm_check_handler
 458 pgm_check_handler:
 459 /*
 460  * First we need to check for a special case:
 461  * Single stepping an instruction that disables the PER event mask will
 462  * cause a PER event AFTER the mask has been set. Example: SVC or LPSW.
 463  * For a single stepped SVC the program check handler gets control after
 464  * the SVC new PSW has been loaded. But we want to execute the SVC first and
 465  * then handle the PER event. Therefore we update the SVC old PSW to point
 466  * to the pgm_check_handler and branch to the SVC handler after we checked
 467  * if we have to load the kernel stack register.
 468  * For every other possible cause for PER event without the PER mask set
 469  * we just ignore the PER event (FIXME: is there anything we have to do
 470  * for LPSW?).
 471  */
 472         STORE_TIMER __LC_SYNC_ENTER_TIMER
 473         SAVE_ALL_BASE __LC_SAVE_AREA
 474         tm      __LC_PGM_INT_CODE+1,0x80 # check whether we got a per exception
 475         jnz     pgm_per                  # got per exception -> special case
 476         SAVE_ALL_SYNC __LC_PGM_OLD_PSW,__LC_SAVE_AREA
 477         CREATE_STACK_FRAME __LC_PGM_OLD_PSW,__LC_SAVE_AREA
 478 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
 479         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
 480         jz      pgm_no_vtime
 481         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
 482         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 483         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
 484 pgm_no_vtime:
 485 #endif
 486         lg      %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
 487         mvc     SP_ARGS(8,%r15),__LC_LAST_BREAK
 488         TRACE_IRQS_OFF
 489         lgf     %r3,__LC_PGM_ILC        # load program interruption code
 490         lghi    %r8,0x7f
 491         ngr     %r8,%r3
 492 pgm_do_call:
 493         sll     %r8,3
 494         larl    %r1,pgm_check_table
 495         lg      %r1,0(%r8,%r1)          # load address of handler routine
 496         la      %r2,SP_PTREGS(%r15)     # address of register-save area
 497         larl    %r14,sysc_return
 498         br      %r1                     # branch to interrupt-handler
 499
 500 #
 501 # handle per exception
 502 #
 503 pgm_per:
 504         tm      __LC_PGM_OLD_PSW,0x40   # test if per event recording is on
 505         jnz     pgm_per_std             # ok, normal per event from user space
 506 # ok its one of the special cases, now we need to find out which one
 507         clc     __LC_PGM_OLD_PSW(16),__LC_SVC_NEW_PSW
 508         je      pgm_svcper
 509 # no interesting special case, ignore PER event
 510         lmg     %r12,%r15,__LC_SAVE_AREA
 511         lpswe   __LC_PGM_OLD_PSW
 512
 513 #
 514 # Normal per exception
 515 #
 516 pgm_per_std:
 517         SAVE_ALL_SYNC __LC_PGM_OLD_PSW,__LC_SAVE_AREA
 518         CREATE_STACK_FRAME __LC_PGM_OLD_PSW,__LC_SAVE_AREA
 519 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
 520         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
 521         jz      pgm_no_vtime2
 522         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
 523         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 524         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
 525 pgm_no_vtime2:
 526 #endif
 527         lg      %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
 528         TRACE_IRQS_OFF
 529         lg      %r1,__TI_task(%r9)
 530         tm      SP_PSW+1(%r15),0x01     # kernel per event ?
 531         jz      kernel_per
 532         mvc     __THREAD_per+__PER_atmid(2,%r1),__LC_PER_ATMID
 533         mvc     __THREAD_per+__PER_address(8,%r1),__LC_PER_ADDRESS
 534         mvc     __THREAD_per+__PER_access_id(1,%r1),__LC_PER_ACCESS_ID
 535         oi      __TI_flags+7(%r9),_TIF_SINGLE_STEP # set TIF_SINGLE_STEP
 536         lgf     %r3,__LC_PGM_ILC        # load program interruption code
 537         lghi    %r8,0x7f
 538         ngr     %r8,%r3                 # clear per-event-bit and ilc
 539         je      sysc_return
 540         j       pgm_do_call
 541
 542 #
 543 # it was a single stepped SVC that is causing all the trouble
 544 #
 545 pgm_svcper:
 546         SAVE_ALL_SYNC __LC_SVC_OLD_PSW,__LC_SAVE_AREA
 547         CREATE_STACK_FRAME __LC_SVC_OLD_PSW,__LC_SAVE_AREA
 548 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
 549         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
 550         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 551         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
 552 #endif
 553         llgh    %r7,__LC_SVC_INT_CODE   # get svc number from lowcore
 554         lg      %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
 555         lg      %r1,__TI_task(%r9)
 556         mvc     __THREAD_per+__PER_atmid(2,%r1),__LC_PER_ATMID
 557         mvc     __THREAD_per+__PER_address(8,%r1),__LC_PER_ADDRESS
 558         mvc     __THREAD_per+__PER_access_id(1,%r1),__LC_PER_ACCESS_ID
 559         oi      __TI_flags+7(%r9),_TIF_SINGLE_STEP # set TIF_SINGLE_STEP
 560         TRACE_IRQS_ON
 561         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
 562         j       sysc_do_svc
 563
 564 #
 565 # per was called from kernel, must be kprobes
 566 #
 567 kernel_per:
 568         xc      SP_SVCNR(2,%r15),SP_SVCNR(%r15) # clear svc number
 569         la      %r2,SP_PTREGS(%r15)     # address of register-save area
 570         larl    %r14,sysc_restore       # load adr. of system ret, no work
 571         jg      do_single_step          # branch to do_single_step
 572
 573 /*
 574  * IO interrupt handler routine
 575  */
 576         .globl io_int_handler
 577 io_int_handler:
 578         STORE_TIMER __LC_ASYNC_ENTER_TIMER
 579         stck    __LC_INT_CLOCK
 580         SAVE_ALL_BASE __LC_SAVE_AREA+32
 581         SAVE_ALL_ASYNC __LC_IO_OLD_PSW,__LC_SAVE_AREA+32
 582         CREATE_STACK_FRAME __LC_IO_OLD_PSW,__LC_SAVE_AREA+32
 583 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
 584         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
 585         jz      io_no_vtime
 586         UPDATE_VTIME __LC_EXIT_TIMER,__LC_ASYNC_ENTER_TIMER,__LC_USER_TIMER
 587         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 588         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_ASYNC_ENTER_TIMER
 589 io_no_vtime:
 590 #endif
 591         lg      %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
 592         TRACE_IRQS_OFF
 593         la      %r2,SP_PTREGS(%r15)     # address of register-save area
 594         brasl   %r14,do_IRQ             # call standard irq handler
 595 io_return:
 596         tm      __TI_flags+7(%r9),_TIF_WORK_INT
 597         jnz     io_work                 # there is work to do (signals etc.)
 598 io_restore:
 599 #ifdef CONFIG_TRACE_IRQFLAGS
 600         larl    %r1,io_restore_trace_psw
 601         lpswe   0(%r1)
 602 io_restore_trace:
 603         TRACE_IRQS_CHECK
 604         LOCKDEP_SYS_EXIT
 605 #endif
 606 io_leave:
 607         RESTORE_ALL __LC_RETURN_PSW,0
 608 io_done:
 609
 610 #ifdef CONFIG_TRACE_IRQFLAGS
 611         .align  8
 612         .globl io_restore_trace_psw
 613 io_restore_trace_psw:
 614         .quad   0, io_restore_trace
 615 #endif
 616
 617 #
 618 # There is work todo, we need to check if we return to userspace, then
 619 # check, if we are in SIE, if yes leave it
 620 #
 621 io_work:
 622         tm      SP_PSW+1(%r15),0x01     # returning to user ?
 623 #ifndef CONFIG_PREEMPT
 624 #if defined(CONFIG_KVM) || defined(CONFIG_KVM_MODULE)
 625         jnz     io_work_user            # yes -> no need to check for SIE
 626         la      %r1, BASED(sie_opcode)  # we return to kernel here
 627         lg      %r2, SP_PSW+8(%r15)
 628         clc     0(2,%r1), 0(%r2)        # is current instruction = SIE?
 629         jne     io_restore              # no-> return to kernel
 630         lg      %r1, SP_PSW+8(%r15)     # yes-> add 4 bytes to leave SIE
 631         aghi    %r1, 4
 632         stg     %r1, SP_PSW+8(%r15)
 633         j       io_restore              # return to kernel
 634 #else
 635         jno     io_restore              # no-> skip resched & signal
 636 #endif
 637 #else
 638         jnz     io_work_user            # yes -> do resched & signal
 639 #if defined(CONFIG_KVM) || defined(CONFIG_KVM_MODULE)
 640         la      %r1, BASED(sie_opcode)
 641         lg      %r2, SP_PSW+8(%r15)
 642         clc     0(2,%r1), 0(%r2)        # is current instruction = SIE?
 643         jne     0f                      # no -> leave PSW alone
 644         lg      %r1, SP_PSW+8(%r15)     # yes-> add 4 bytes to leave SIE
 645         aghi    %r1, 4
 646         stg     %r1, SP_PSW+8(%r15)
 647 0:
 648 #endif
 649         # check for preemptive scheduling
 650         icm     %r0,15,__TI_precount(%r9)
 651         jnz     io_restore              # preemption is disabled
 652         # switch to kernel stack
 653         lg      %r1,SP_R15(%r15)
 654         aghi    %r1,-SP_SIZE
 655         mvc     SP_PTREGS(__PT_SIZE,%r1),SP_PTREGS(%r15)
 656         xc      __SF_BACKCHAIN(8,%r1),__SF_BACKCHAIN(%r1) # clear back chain
 657         lgr     %r15,%r1
 658 io_resume_loop:
 659         tm      __TI_flags+7(%r9),_TIF_NEED_RESCHED
 660         jno     io_restore
 661         larl    %r14,io_resume_loop
 662         jg      preempt_schedule_irq
 663 #endif
 664
 665 io_work_user:
 666         lg      %r1,__LC_KERNEL_STACK
 667         aghi    %r1,-SP_SIZE
 668         mvc     SP_PTREGS(__PT_SIZE,%r1),SP_PTREGS(%r15)
 669         xc      __SF_BACKCHAIN(8,%r1),__SF_BACKCHAIN(%r1) # clear back chain
 670         lgr     %r15,%r1
 671 #
 672 # One of the work bits is on. Find out which one.
 673 # Checked are: _TIF_SIGPENDING, _TIF_RESTORE_SIGPENDING, _TIF_NEED_RESCHED
 674 #              and _TIF_MCCK_PENDING
 675 #
 676 io_work_loop:
 677         tm      __TI_flags+7(%r9),_TIF_MCCK_PENDING
 678         jo      io_mcck_pending
 679         tm      __TI_flags+7(%r9),_TIF_NEED_RESCHED
 680         jo      io_reschedule
 681         tm      __TI_flags+7(%r9),_TIF_SIGPENDING
 682         jnz     io_sigpending
 683         tm      __TI_flags+7(%r9),_TIF_NOTIFY_RESUME
 684         jnz     io_notify_resume
 685         j       io_restore
 686 io_work_done:
 687
 688 #if defined(CONFIG_KVM) || defined(CONFIG_KVM_MODULE)
 689 sie_opcode:
 690         .long 0xb2140000
 691 #endif
 692
 693 #
 694 # _TIF_MCCK_PENDING is set, call handler
 695 #
 696 io_mcck_pending:
 697         brasl   %r14,s390_handle_mcck   # TIF bit will be cleared by handler
 698         j       io_work_loop
 699
 700 #
 701 # _TIF_NEED_RESCHED is set, call schedule
 702 #
 703 io_reschedule:
 704         TRACE_IRQS_ON
 705         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
 706         brasl   %r14,schedule           # call scheduler
 707         stnsm   __SF_EMPTY(%r15),0xfc   # disable I/O and ext. interrupts
 708         TRACE_IRQS_OFF
 709         tm      __TI_flags+7(%r9),_TIF_WORK_INT
 710         jz      io_restore              # there is no work to do
 711         j       io_work_loop
 712
 713 #
 714 # _TIF_SIGPENDING or is set, call do_signal
 715 #
 716 io_sigpending:
 717         TRACE_IRQS_ON
 718         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
 719         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 720         brasl   %r14,do_signal          # call do_signal
 721         stnsm   __SF_EMPTY(%r15),0xfc   # disable I/O and ext. interrupts
 722         TRACE_IRQS_OFF
 723         j       io_work_loop
 724
 725 #
 726 # _TIF_NOTIFY_RESUME or is set, call do_notify_resume
 727 #
 728 io_notify_resume:
 729         TRACE_IRQS_ON
 730         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
 731         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 732         brasl   %r14,do_notify_resume   # call do_notify_resume
 733         stnsm   __SF_EMPTY(%r15),0xfc   # disable I/O and ext. interrupts
 734         TRACE_IRQS_OFF
 735         j       io_work_loop
 736
 737 /*
 738  * External interrupt handler routine
 739  */
 740         .globl  ext_int_handler
 741 ext_int_handler:
 742         STORE_TIMER __LC_ASYNC_ENTER_TIMER
 743         stck    __LC_INT_CLOCK
 744         SAVE_ALL_BASE __LC_SAVE_AREA+32
 745         SAVE_ALL_ASYNC __LC_EXT_OLD_PSW,__LC_SAVE_AREA+32
 746         CREATE_STACK_FRAME __LC_EXT_OLD_PSW,__LC_SAVE_AREA+32
 747 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
 748         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
 749         jz      ext_no_vtime
 750         UPDATE_VTIME __LC_EXIT_TIMER,__LC_ASYNC_ENTER_TIMER,__LC_USER_TIMER
 751         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 752         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_ASYNC_ENTER_TIMER
 753 ext_no_vtime:
 754 #endif
 755         lg      %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
 756         TRACE_IRQS_OFF
 757         la      %r2,SP_PTREGS(%r15)     # address of register-save area
 758         llgh    %r3,__LC_EXT_INT_CODE   # get interruption code
 759         brasl   %r14,do_extint
 760         j       io_return
 761
 762 __critical_end:
 763
 764 /*
 765  * Machine check handler routines
 766  */
 767         .globl mcck_int_handler
 768 mcck_int_handler:
 769         la      %r1,4095                # revalidate r1
 770         spt     __LC_CPU_TIMER_SAVE_AREA-4095(%r1)      # revalidate cpu timer
 771         lmg     %r0,%r15,__LC_GPREGS_SAVE_AREA-4095(%r1)# revalidate gprs
 772         SAVE_ALL_BASE __LC_SAVE_AREA+64
 773         la      %r12,__LC_MCK_OLD_PSW
 774         tm      __LC_MCCK_CODE,0x80     # system damage?
 775         jo      mcck_int_main           # yes -> rest of mcck code invalid
 776 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
 777         la      %r14,4095
 778         mvc     __LC_SAVE_AREA+104(8),__LC_ASYNC_ENTER_TIMER
 779         mvc     __LC_ASYNC_ENTER_TIMER(8),__LC_CPU_TIMER_SAVE_AREA-4095(%r14)
 780         tm      __LC_MCCK_CODE+5,0x02   # stored cpu timer value valid?
 781         jo      1f
 782         la      %r14,__LC_SYNC_ENTER_TIMER
 783         clc     0(8,%r14),__LC_ASYNC_ENTER_TIMER
 784         jl      0f
 785         la      %r14,__LC_ASYNC_ENTER_TIMER
 786 0:      clc     0(8,%r14),__LC_EXIT_TIMER
 787         jl      0f
 788         la      %r14,__LC_EXIT_TIMER
 789 0:      clc     0(8,%r14),__LC_LAST_UPDATE_TIMER
 790         jl      0f
 791         la      %r14,__LC_LAST_UPDATE_TIMER
 792 0:      spt     0(%r14)
 793         mvc     __LC_ASYNC_ENTER_TIMER(8),0(%r14)
 794 1:
 795 #endif
 796         tm      __LC_MCCK_CODE+2,0x09   # mwp + ia of old psw valid?
 797         jno     mcck_int_main           # no -> skip cleanup critical
 798         tm      __LC_MCK_OLD_PSW+1,0x01 # test problem state bit
 799         jnz     mcck_int_main           # from user -> load kernel stack
 800         clc     __LC_MCK_OLD_PSW+8(8),BASED(.Lcritical_end)
 801         jhe     mcck_int_main
 802         clc     __LC_MCK_OLD_PSW+8(8),BASED(.Lcritical_start)
 803         jl      mcck_int_main
 804         brasl   %r14,cleanup_critical
 805 mcck_int_main:
 806         lg      %r14,__LC_PANIC_STACK   # are we already on the panic stack?
 807         slgr    %r14,%r15
 808         srag    %r14,%r14,PAGE_SHIFT
 809         jz      0f
 810         lg      %r15,__LC_PANIC_STACK   # load panic stack
 811 0:      CREATE_STACK_FRAME __LC_MCK_OLD_PSW,__LC_SAVE_AREA+64
 812 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
 813         tm      __LC_MCCK_CODE+2,0x08   # mwp of old psw valid?
 814         jno     mcck_no_vtime           # no -> no timer update
 815         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
 816         jz      mcck_no_vtime
 817         UPDATE_VTIME __LC_EXIT_TIMER,__LC_ASYNC_ENTER_TIMER,__LC_USER_TIMER
 818         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 819         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_ASYNC_ENTER_TIMER
 820 mcck_no_vtime:
 821 #endif
 822         lg      %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
 823         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 824         brasl   %r14,s390_do_machine_check
 825         tm      SP_PSW+1(%r15),0x01     # returning to user ?
 826         jno     mcck_return
 827         lg      %r1,__LC_KERNEL_STACK   # switch to kernel stack
 828         aghi    %r1,-SP_SIZE
 829         mvc     SP_PTREGS(__PT_SIZE,%r1),SP_PTREGS(%r15)
 830         xc      __SF_BACKCHAIN(8,%r1),__SF_BACKCHAIN(%r1) # clear back chain
 831         lgr     %r15,%r1
 832         stosm   __SF_EMPTY(%r15),0x04   # turn dat on
 833         tm      __TI_flags+7(%r9),_TIF_MCCK_PENDING
 834         jno     mcck_return
 835         TRACE_IRQS_OFF
 836         brasl   %r14,s390_handle_mcck
 837         TRACE_IRQS_ON
 838 mcck_return:
 839         mvc     __LC_RETURN_MCCK_PSW(16),SP_PSW(%r15) # move return PSW
 840         ni      __LC_RETURN_MCCK_PSW+1,0xfd # clear wait state bit
 841         lmg     %r0,%r15,SP_R0(%r15)    # load gprs 0-15
 842 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
 843         mvc     __LC_ASYNC_ENTER_TIMER(8),__LC_SAVE_AREA+104
 844         tm      __LC_RETURN_MCCK_PSW+1,0x01 # returning to user ?
 845         jno     0f
 846         stpt    __LC_EXIT_TIMER
 847 0:
 848 #endif
 849         lpswe   __LC_RETURN_MCCK_PSW    # back to caller
 850
 851 /*
 852  * Restart interruption handler, kick starter for additional CPUs
 853  */
 854 #ifdef CONFIG_SMP
 855         __CPUINIT
 856         .globl restart_int_handler
 857 restart_int_handler:
 858         lg      %r15,__LC_SAVE_AREA+120 # load ksp
 859         lghi    %r10,__LC_CREGS_SAVE_AREA
 860         lctlg   %c0,%c15,0(%r10) # get new ctl regs
 861         lghi    %r10,__LC_AREGS_SAVE_AREA
 862         lam     %a0,%a15,0(%r10)
 863         lmg     %r6,%r15,__SF_GPRS(%r15) # load registers from clone
 864         stosm   __SF_EMPTY(%r15),0x04   # now we can turn dat on
 865         jg      start_secondary
 866         .previous
 867 #else
 868 /*
 869  * If we do not run with SMP enabled, let the new CPU crash ...
 870  */
 871         .globl restart_int_handler
 872 restart_int_handler:
 873         basr    %r1,0
 874 restart_base:
 875         lpswe   restart_crash-restart_base(%r1)
 876         .align 8
 877 restart_crash:
 878         .long  0x000a0000,0x00000000,0x00000000,0x00000000
 879 restart_go:
 880 #endif
 881
 882 #ifdef CONFIG_CHECK_STACK
 883 /*
 884  * The synchronous or the asynchronous stack overflowed. We are dead.
 885  * No need to properly save the registers, we are going to panic anyway.
 886  * Setup a pt_regs so that show_trace can provide a good call trace.
 887  */
 888 stack_overflow:
 889         lg      %r15,__LC_PANIC_STACK   # change to panic stack
 890         aghi    %r15,-SP_SIZE
 891         mvc     SP_PSW(16,%r15),0(%r12) # move user PSW to stack
 892         stmg    %r0,%r11,SP_R0(%r15)    # store gprs %r0-%r11 to kernel stack
 893         la      %r1,__LC_SAVE_AREA
 894         chi     %r12,__LC_SVC_OLD_PSW
 895         je      0f
 896         chi     %r12,__LC_PGM_OLD_PSW
 897         je      0f
 898         la      %r1,__LC_SAVE_AREA+32
 899 0:      mvc     SP_R12(32,%r15),0(%r1)  # move %r12-%r15 to stack
 900         mvc     SP_ARGS(8,%r15),__LC_LAST_BREAK
 901         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15) # clear back chain
 902         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 903         jg      kernel_stack_overflow
 904 #endif
 905
 906 cleanup_table_system_call:
 907         .quad   system_call, sysc_do_svc
 908 cleanup_table_sysc_return:
 909         .quad   sysc_return, sysc_leave
 910 cleanup_table_sysc_leave:
 911         .quad   sysc_leave, sysc_done
 912 cleanup_table_sysc_work_loop:
 913         .quad   sysc_work_loop, sysc_work_done
 914 cleanup_table_io_return:
 915         .quad   io_return, io_leave
 916 cleanup_table_io_leave:
 917         .quad   io_leave, io_done
 918 cleanup_table_io_work_loop:
 919         .quad   io_work_loop, io_work_done
 920
 921 cleanup_critical:
 922         clc     8(8,%r12),BASED(cleanup_table_system_call)
 923         jl      0f
 924         clc     8(8,%r12),BASED(cleanup_table_system_call+8)
 925         jl      cleanup_system_call
 926 0:
 927         clc     8(8,%r12),BASED(cleanup_table_sysc_return)
 928         jl      0f
 929         clc     8(8,%r12),BASED(cleanup_table_sysc_return+8)
 930         jl      cleanup_sysc_return
 931 0:
 932         clc     8(8,%r12),BASED(cleanup_table_sysc_leave)
 933         jl      0f
 934         clc     8(8,%r12),BASED(cleanup_table_sysc_leave+8)
 935         jl      cleanup_sysc_leave
 936 0:
 937         clc     8(8,%r12),BASED(cleanup_table_sysc_work_loop)
 938         jl      0f
 939         clc     8(8,%r12),BASED(cleanup_table_sysc_work_loop+8)
 940         jl      cleanup_sysc_return
 941 0:
 942         clc     8(8,%r12),BASED(cleanup_table_io_return)
 943         jl      0f
 944         clc     8(8,%r12),BASED(cleanup_table_io_return+8)
 945         jl      cleanup_io_return
 946 0:
 947         clc     8(8,%r12),BASED(cleanup_table_io_leave)
 948         jl      0f
 949         clc     8(8,%r12),BASED(cleanup_table_io_leave+8)
 950         jl      cleanup_io_leave
 951 0:
 952         clc     8(8,%r12),BASED(cleanup_table_io_work_loop)
 953         jl      0f
 954         clc     8(8,%r12),BASED(cleanup_table_io_work_loop+8)
 955         jl      cleanup_io_return
 956 0:
 957         br      %r14
 958
 959 cleanup_system_call:
 960         mvc     __LC_RETURN_PSW(16),0(%r12)
 961         cghi    %r12,__LC_MCK_OLD_PSW
 962         je      0f
 963         la      %r12,__LC_SAVE_AREA+32
 964         j       1f
 965 0:      la      %r12,__LC_SAVE_AREA+64
 966 1:
 967 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
 968         clc     __LC_RETURN_PSW+8(8),BASED(cleanup_system_call_insn+8)
 969         jh      0f
 970         mvc     __LC_SYNC_ENTER_TIMER(8),__LC_ASYNC_ENTER_TIMER
 971 0:      clc     __LC_RETURN_PSW+8(8),BASED(cleanup_system_call_insn+16)
 972         jhe     cleanup_vtime
 973 #endif
 974         clc     __LC_RETURN_PSW+8(8),BASED(cleanup_system_call_insn)
 975         jh      0f
 976         mvc     __LC_SAVE_AREA(32),0(%r12)
 977 0:      stg     %r13,8(%r12)
 978         stg     %r12,__LC_SAVE_AREA+96  # argh
 979         SAVE_ALL_SYNC __LC_SVC_OLD_PSW,__LC_SAVE_AREA
 980         CREATE_STACK_FRAME __LC_SVC_OLD_PSW,__LC_SAVE_AREA
 981         lg      %r12,__LC_SAVE_AREA+96  # argh
 982         stg     %r15,24(%r12)
 983         llgh    %r7,__LC_SVC_INT_CODE
 984 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
 985 cleanup_vtime:
 986         clc     __LC_RETURN_PSW+8(8),BASED(cleanup_system_call_insn+24)
 987         jhe     cleanup_stime
 988         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
 989 cleanup_stime:
 990         clc     __LC_RETURN_PSW+8(8),BASED(cleanup_system_call_insn+32)
 991         jh      cleanup_update
 992         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 993 cleanup_update:
 994         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
 995 #endif
 996         mvc     __LC_RETURN_PSW+8(8),BASED(cleanup_table_system_call+8)
 997         la      %r12,__LC_RETURN_PSW
 998         br      %r14
 999 cleanup_system_call_insn:
1000         .quad   sysc_saveall
1001 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
1002         .quad   system_call
1003         .quad   sysc_vtime
1004         .quad   sysc_stime
1005         .quad   sysc_update
1006 #endif
1007
1008 cleanup_sysc_return:
1009         mvc     __LC_RETURN_PSW(8),0(%r12)
1010         mvc     __LC_RETURN_PSW+8(8),BASED(cleanup_table_sysc_return)
1011         la      %r12,__LC_RETURN_PSW
1012         br      %r14
1013
1014 cleanup_sysc_leave:
1015         clc     8(8,%r12),BASED(cleanup_sysc_leave_insn)
1016         je      2f
1017 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
1018         mvc     __LC_EXIT_TIMER(8),__LC_ASYNC_ENTER_TIMER
1019         clc     8(8,%r12),BASED(cleanup_sysc_leave_insn+8)
1020         je      2f
1021 #endif
1022         mvc     __LC_RETURN_PSW(16),SP_PSW(%r15)
1023         cghi    %r12,__LC_MCK_OLD_PSW
1024         jne     0f
1025         mvc     __LC_SAVE_AREA+64(32),SP_R12(%r15)
1026         j       1f
1027 0:      mvc     __LC_SAVE_AREA+32(32),SP_R12(%r15)
1028 1:      lmg     %r0,%r11,SP_R0(%r15)
1029         lg      %r15,SP_R15(%r15)
1030 2:      la      %r12,__LC_RETURN_PSW
1031         br      %r14
1032 cleanup_sysc_leave_insn:
1033         .quad   sysc_done - 4
1034 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
1035         .quad   sysc_done - 8
1036 #endif
1037
1038 cleanup_io_return:
1039         mvc     __LC_RETURN_PSW(8),0(%r12)
1040         mvc     __LC_RETURN_PSW+8(8),BASED(cleanup_table_io_work_loop)
1041         la      %r12,__LC_RETURN_PSW
1042         br      %r14
1043
1044 cleanup_io_leave:
1045         clc     8(8,%r12),BASED(cleanup_io_leave_insn)
1046         je      2f
1047 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
1048         mvc     __LC_EXIT_TIMER(8),__LC_ASYNC_ENTER_TIMER
1049         clc     8(8,%r12),BASED(cleanup_io_leave_insn+8)
1050         je      2f
1051 #endif
1052         mvc     __LC_RETURN_PSW(16),SP_PSW(%r15)
1053         cghi    %r12,__LC_MCK_OLD_PSW
1054         jne     0f
1055         mvc     __LC_SAVE_AREA+64(32),SP_R12(%r15)
1056         j       1f
1057 0:      mvc     __LC_SAVE_AREA+32(32),SP_R12(%r15)
1058 1:      lmg     %r0,%r11,SP_R0(%r15)
1059         lg      %r15,SP_R15(%r15)
1060 2:      la      %r12,__LC_RETURN_PSW
1061         br      %r14
1062 cleanup_io_leave_insn:
1063         .quad   io_done - 4
1064 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
1065         .quad   io_done - 8
1066 #endif
1067
1068 /*
1069  * Integer constants
1070  */
1071                 .align  4
1072 .Lconst:
1073 .Lnr_syscalls:  .long   NR_syscalls
1074 .L0x0130:       .short  0x130
1075 .L0x0140:       .short  0x140
1076 .L0x0150:       .short  0x150
1077 .L0x0160:       .short  0x160
1078 .L0x0170:       .short  0x170
1079 .Lcritical_start:
1080                 .quad   __critical_start
1081 .Lcritical_end:
1082                 .quad   __critical_end
1083
1084                 .section .rodata, "a"
1085 #define SYSCALL(esa,esame,emu)  .long esame
1086 sys_call_table:
1087 #include "syscalls.S"
1088 #undef SYSCALL
1089
1090 #ifdef CONFIG_COMPAT
1091
1092 #define SYSCALL(esa,esame,emu)  .long emu
1093 sys_call_table_emu:
1094 #include "syscalls.S"
1095 #undef SYSCALL
1096 #endif