arch/i386/kernel/vmlinux.lds.S

   1 /* ld script to make i386 Linux kernel
   2  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>;
   3  */
   4
   5 #define LOAD_OFFSET __PAGE_OFFSET
   6
   7 #include <asm-generic/vmlinux.lds.h>
   8 #include <asm/thread_info.h>
   9 #include <asm/page.h>
  10 #include <asm/cache.h>
  11
  12 OUTPUT_FORMAT("elf32-i386", "elf32-i386", "elf32-i386")
  13 OUTPUT_ARCH(i386)
  14 ENTRY(phys_startup_32)
  15 jiffies = jiffies_64;
  16 SECTIONS
  17 {
  18   . = __KERNEL_START;
  19   phys_startup_32 = startup_32 - LOAD_OFFSET;
  20   /* read-only */
  21   _text = .;                    /* Text and read-only data */
  22   .text : AT(ADDR(.text) - LOAD_OFFSET) {
  23         *(.text)
  24         SCHED_TEXT
  25         LOCK_TEXT
  26         KPROBES_TEXT
  27         *(.fixup)
  28         *(.gnu.warning)
  29         } = 0x9090
  30
  31   _etext = .;                   /* End of text section */
  32
  33   . = ALIGN(16);                /* Exception table */
  34   __start___ex_table = .;
  35   __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) { *(__ex_table) }
  36   __stop___ex_table = .;
  37
  38   RODATA
  39
  40   /* writeable */
  41   .data : AT(ADDR(.data) - LOAD_OFFSET) {       /* Data */
  42         *(.data)
  43         CONSTRUCTORS
  44         }
  45
  46   . = ALIGN(4096);
  47   __nosave_begin = .;
  48   .data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) { *(.data.nosave) }
  49   . = ALIGN(4096);
  50   __nosave_end = .;
  51
  52   . = ALIGN(4096);
  53   .data.page_aligned : AT(ADDR(.data.page_aligned) - LOAD_OFFSET) {
  54         *(.data.idt)
  55   }
  56
  57   . = ALIGN(32);
  58   .data.cacheline_aligned : AT(ADDR(.data.cacheline_aligned) - LOAD_OFFSET) {
  59         *(.data.cacheline_aligned)
  60   }
  61
  62   /* rarely changed data like cpu maps */
  63   . = ALIGN(32);
  64   .data.read_mostly : AT(ADDR(.data.read_mostly) - LOAD_OFFSET) { *(.data.read_mostly) }
  65   _edata = .;                   /* End of data section */
  66
  67   . = ALIGN(THREAD_SIZE);       /* init_task */
  68   .data.init_task : AT(ADDR(.data.init_task) - LOAD_OFFSET) {
  69         *(.data.init_task)
  70   }
  71
  72   /* will be freed after init */
  73   . = ALIGN(4096);              /* Init code and data */
  74   __init_begin = .;
  75   .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) {
  76         _sinittext = .;
  77         *(.init.text)
  78         _einittext = .;
  79   }
  80   .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) { *(.init.data) }
  81   . = ALIGN(16);
  82   __setup_start = .;
  83   .init.setup : AT(ADDR(.init.setup) - LOAD_OFFSET) { *(.init.setup) }
  84   __setup_end = .;
  85   __initcall_start = .;
  86   .initcall.init : AT(ADDR(.initcall.init) - LOAD_OFFSET) {
  87         *(.initcall1.init)
  88         *(.initcall2.init)
  89         *(.initcall3.init)
  90         *(.initcall4.init)
  91         *(.initcall5.init)
  92         *(.initcall6.init)
  93         *(.initcall7.init)
  94   }
  95   __initcall_end = .;
  96   __con_initcall_start = .;
  97   .con_initcall.init : AT(ADDR(.con_initcall.init) - LOAD_OFFSET) {
  98         *(.con_initcall.init)
  99   }
 100   __con_initcall_end = .;
 101   SECURITY_INIT
 102   . = ALIGN(4);
 103   __alt_instructions = .;
 104   .altinstructions : AT(ADDR(.altinstructions) - LOAD_OFFSET) {
 105         *(.altinstructions)
 106   }
 107   __alt_instructions_end = .;
 108   .altinstr_replacement : AT(ADDR(.altinstr_replacement) - LOAD_OFFSET) {
 109         *(.altinstr_replacement)
 110   }
 111   /* .exit.text is discard at runtime, not link time, to deal with references
 112      from .altinstructions and .eh_frame */
 113   .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) { *(.exit.text) }
 114   .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) { *(.exit.data) }
 115   . = ALIGN(4096);
 116   __initramfs_start = .;
 117   .init.ramfs : AT(ADDR(.init.ramfs) - LOAD_OFFSET) { *(.init.ramfs) }
 118   __initramfs_end = .;
 119   . = ALIGN(L1_CACHE_BYTES);
 120   __per_cpu_start = .;
 121   .data.percpu  : AT(ADDR(.data.percpu) - LOAD_OFFSET) { *(.data.percpu) }
 122   __per_cpu_end = .;
 123   . = ALIGN(4096);
 124   __init_end = .;
 125   /* freed after init ends here */
 126
 127   __bss_start = .;              /* BSS */
 128   .bss.page_aligned : AT(ADDR(.bss.page_aligned) - LOAD_OFFSET) {
 129         *(.bss.page_aligned)
 130   }
 131   .bss : AT(ADDR(.bss) - LOAD_OFFSET) {
 132         *(.bss)
 133   }
 134   . = ALIGN(4);
 135   __bss_stop = .;
 136
 137   _end = . ;
 138
 139   /* This is where the kernel creates the early boot page tables */
 140   . = ALIGN(4096);
 141   pg0 = .;
 142
 143   /* Sections to be discarded */
 144   /DISCARD/ : {
 145         *(.exitcall.exit)
 146         }
 147
 148   STABS_DEBUG
 149
 150   DWARF_DEBUG
 151 }