arch/arm/vfp/vfphw.S

   1 /*
   2  *  linux/arch/arm/vfp/vfphw.S
   3  *
   4  *  Copyright (C) 2004 ARM Limited.
   5  *  Written by Deep Blue Solutions Limited.
   6  *
   7  * This program is free software; you can redistribute it and/or modify
   8  * it under the terms of the GNU General Public License version 2 as
   9  * published by the Free Software Foundation.
  10  *
  11  * This code is called from the kernel's undefined instruction trap.
  12  * r9 holds the return address for successful handling.
  13  * lr holds the return address for unrecognised instructions.
  14  * r10 points at the start of the private FP workspace in the thread structure
  15  * sp points to a struct pt_regs (as defined in include/asm/proc/ptrace.h)
  16  */
  17 #include <asm/thread_info.h>
  18 #include <asm/vfpmacros.h>
  19 #include "../kernel/entry-header.S"
  20
  21         .macro  DBGSTR, str
  22 #ifdef DEBUG
  23         stmfd   sp!, {r0-r3, ip, lr}
  24         add     r0, pc, #4
  25         bl      printk
  26         b       1f
  27         .asciz  "<7>VFP: \str\n"
  28         .balign 4
  29 1:      ldmfd   sp!, {r0-r3, ip, lr}
  30 #endif
  31         .endm
  32
  33         .macro  DBGSTR1, str, arg
  34 #ifdef DEBUG
  35         stmfd   sp!, {r0-r3, ip, lr}
  36         mov     r1, \arg
  37         add     r0, pc, #4
  38         bl      printk
  39         b       1f
  40         .asciz  "<7>VFP: \str\n"
  41         .balign 4
  42 1:      ldmfd   sp!, {r0-r3, ip, lr}
  43 #endif
  44         .endm
  45
  46         .macro  DBGSTR3, str, arg1, arg2, arg3
  47 #ifdef DEBUG
  48         stmfd   sp!, {r0-r3, ip, lr}
  49         mov     r3, \arg3
  50         mov     r2, \arg2
  51         mov     r1, \arg1
  52         add     r0, pc, #4
  53         bl      printk
  54         b       1f
  55         .asciz  "<7>VFP: \str\n"
  56         .balign 4
  57 1:      ldmfd   sp!, {r0-r3, ip, lr}
  58 #endif
  59         .endm
  60
  61
  62 @ VFP hardware support entry point.
  63 @
  64 @  r0  = faulted instruction
  65 @  r2  = faulted PC+4
  66 @  r9  = successful return
  67 @  r10 = vfp_state union
  68 @  r11 = CPU number
  69 @  lr  = failure return
  70
  71         .globl  vfp_support_entry
  72 vfp_support_entry:
  73         DBGSTR3 "instr %08x pc %08x state %p", r0, r2, r10
  74
  75         VFPFMRX r1, FPEXC               @ Is the VFP enabled?
  76         DBGSTR1 "fpexc %08x", r1
  77         tst     r1, #FPEXC_EN
  78         bne     look_for_VFP_exceptions @ VFP is already enabled
  79
  80         DBGSTR1 "enable %x", r10
  81         ldr     r3, last_VFP_context_address
  82         orr     r1, r1, #FPEXC_EN       @ user FPEXC has the enable bit set
  83         ldr     r4, [r3, r11, lsl #2]   @ last_VFP_context pointer
  84         bic     r5, r1, #FPEXC_EX       @ make sure exceptions are disabled
  85         cmp     r4, r10
  86         beq     check_for_exception     @ we are returning to the same
  87                                         @ process, so the registers are
  88                                         @ still there.  In this case, we do
  89                                         @ not want to drop a pending exception.
  90
  91         VFPFMXR FPEXC, r5               @ enable VFP, disable any pending
  92                                         @ exceptions, so we can get at the
  93                                         @ rest of it
  94
  95 #ifndef CONFIG_SMP
  96         @ Save out the current registers to the old thread state
  97         @ No need for SMP since this is not done lazily
  98
  99         DBGSTR1 "save old state %p", r4
 100         cmp     r4, #0
 101         beq     no_old_VFP_process
 102         VFPFMRX r5, FPSCR               @ current status
 103 #ifndef CONFIG_VFPv3
 104         VFPFMRX r6, FPINST              @ FPINST (always there, rev0 onwards)
 105         tst     r1, #FPEXC_FPV2         @ is there an FPINST2 to read?
 106         VFPFMRX r8, FPINST2, NE         @ FPINST2 if needed - avoids reading
 107                                         @ nonexistant reg on rev0
 108 #endif
 109         VFPFSTMIA r4                    @ save the working registers
 110         stmia   r4, {r1, r5, r6, r8}    @ save FPEXC, FPSCR, FPINST, FPINST2
 111                                         @ and point r4 at the word at the
 112                                         @ start of the register dump
 113 #endif
 114
 115 no_old_VFP_process:
 116         DBGSTR1 "load state %p", r10
 117         str     r10, [r3, r11, lsl #2]  @ update the last_VFP_context pointer
 118                                         @ Load the saved state back into the VFP
 119         VFPFLDMIA r10                   @ reload the working registers while
 120                                         @ FPEXC is in a safe state
 121         ldmia   r10, {r1, r5, r6, r8}   @ load FPEXC, FPSCR, FPINST, FPINST2
 122 #ifndef CONFIG_VFPv3
 123         tst     r1, #FPEXC_FPV2         @ is there an FPINST2 to write?
 124         VFPFMXR FPINST2, r8, NE         @ FPINST2 if needed - avoids writing
 125                                         @ nonexistant reg on rev0
 126         VFPFMXR FPINST, r6
 127 #endif
 128         VFPFMXR FPSCR, r5               @ restore status
 129
 130 check_for_exception:
 131         tst     r1, #FPEXC_EX
 132         bne     process_exception       @ might as well handle the pending
 133                                         @ exception before retrying branch
 134                                         @ out before setting an FPEXC that
 135                                         @ stops us reading stuff
 136         VFPFMXR FPEXC, r1               @ restore FPEXC last
 137         sub     r2, r2, #4
 138         str     r2, [sp, #S_PC]         @ retry the instruction
 139         mov     pc, r9                  @ we think we have handled things
 140
 141
 142 look_for_VFP_exceptions:
 143         tst     r1, #FPEXC_EX
 144         bne     process_exception
 145         VFPFMRX r5, FPSCR
 146         tst     r5, #FPSCR_IXE          @ IXE doesn't set FPEXC_EX !
 147         bne     process_exception
 148
 149         @ Fall into hand on to next handler - appropriate coproc instr
 150         @ not recognised by VFP
 151
 152         DBGSTR  "not VFP"
 153         mov     pc, lr
 154
 155 process_exception:
 156         DBGSTR  "bounce"
 157         sub     r2, r2, #4
 158         str     r2, [sp, #S_PC]         @ retry the instruction on exit from
 159                                         @ the imprecise exception handling in
 160                                         @ the support code
 161         mov     r2, sp                  @ nothing stacked - regdump is at TOS
 162         mov     lr, r9                  @ setup for a return to the user code.
 163
 164         @ Now call the C code to package up the bounce to the support code
 165         @   r0 holds the trigger instruction
 166         @   r1 holds the FPEXC value
 167         @   r2 pointer to register dump
 168         b       VFP9_bounce             @ we have handled this - the support
 169                                         @ code will raise an exception if
 170                                         @ required. If not, the user code will
 171                                         @ retry the faulted instruction
 172
 173 #ifdef CONFIG_SMP
 174         .globl  vfp_save_state
 175         .type   vfp_save_state, %function
 176 vfp_save_state:
 177         @ Save the current VFP state
 178         @ r0 - save location
 179         @ r1 - FPEXC
 180         DBGSTR1 "save VFP state %p", r0
 181         VFPFMRX r2, FPSCR               @ current status
 182 #ifndef CONFIG_VFPv3
 183         VFPFMRX r3, FPINST              @ FPINST (always there, rev0 onwards)
 184         tst     r1, #FPEXC_FPV2         @ is there an FPINST2 to read?
 185         VFPFMRX r12, FPINST2, NE        @ FPINST2 if needed - avoids reading
 186                                         @ nonexistant reg on rev0
 187 #endif
 188         VFPFSTMIA r0                    @ save the working registers
 189         stmia   r0, {r1, r2, r3, r12}   @ save FPEXC, FPSCR, FPINST, FPINST2
 190         mov     pc, lr
 191 #endif
 192
 193 last_VFP_context_address:
 194         .word   last_VFP_context
 195
 196         .globl  vfp_get_float
 197 vfp_get_float:
 198         add     pc, pc, r0, lsl #3
 199         mov     r0, r0
 200         .irp    dr,0,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15
 201         mrc     p10, 0, r0, c\dr, c0, 0 @ fmrs  r0, s0
 202         mov     pc, lr
 203         mrc     p10, 0, r0, c\dr, c0, 4 @ fmrs  r0, s1
 204         mov     pc, lr
 205         .endr
 206
 207         .globl  vfp_put_float
 208 vfp_put_float:
 209         add     pc, pc, r1, lsl #3
 210         mov     r0, r0
 211         .irp    dr,0,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15
 212         mcr     p10, 0, r0, c\dr, c0, 0 @ fmsr  r0, s0
 213         mov     pc, lr
 214         mcr     p10, 0, r0, c\dr, c0, 4 @ fmsr  r0, s1
 215         mov     pc, lr
 216         .endr
 217
 218         .globl  vfp_get_double
 219 vfp_get_double:
 220         add     pc, pc, r0, lsl #3
 221         mov     r0, r0
 222         .irp    dr,0,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15
 223         fmrrd   r0, r1, d\dr
 224         mov     pc, lr
 225         .endr
 226 #ifdef CONFIG_VFPv3
 227         @ d16 - d31 registers
 228         .irp    dr,0,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15
 229         mrrc    p11, 3, r0, r1, c\dr    @ fmrrd r0, r1, d\dr
 230         mov     pc, lr
 231         .endr
 232 #endif
 233
 234         @ virtual register 16 (or 32 if VFPv3) for compare with zero
 235         mov     r0, #0
 236         mov     r1, #0
 237         mov     pc, lr
 238
 239         .globl  vfp_put_double
 240 vfp_put_double:
 241         add     pc, pc, r2, lsl #3
 242         mov     r0, r0
 243         .irp    dr,0,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15
 244         fmdrr   d\dr, r0, r1
 245         mov     pc, lr
 246         .endr
 247 #ifdef CONFIG_VFPv3
 248         @ d16 - d31 registers
 249         .irp    dr,0,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15
 250         mcrr    p11, 3, r1, r2, c\dr    @ fmdrr r1, r2, d\dr
 251         mov     pc, lr
 252         .endr
 253 #endif