arch/arm/mm/proc-v6.S

   1 /*
   2  *  linux/arch/arm/mm/proc-v6.S
   3  *
   4  *  Copyright (C) 2001 Deep Blue Solutions Ltd.
   5  *  Modified by Catalin Marinas for noMMU support
   6  *
   7  * This program is free software; you can redistribute it and/or modify
   8  * it under the terms of the GNU General Public License version 2 as
   9  * published by the Free Software Foundation.
  10  *
  11  *  This is the "shell" of the ARMv6 processor support.
  12  */
  13 #include <linux/linkage.h>
  14 #include <asm/assembler.h>
  15 #include <asm/asm-offsets.h>
  16 #include <asm/elf.h>
  17 #include <asm/pgtable-hwdef.h>
  18 #include <asm/pgtable.h>
  19
  20 #include "proc-macros.S"
  21
  22 #define D_CACHE_LINE_SIZE       32
  23
  24 #define TTB_C           (1 << 0)
  25 #define TTB_S           (1 << 1)
  26 #define TTB_IMP         (1 << 2)
  27 #define TTB_RGN_NC      (0 << 3)
  28 #define TTB_RGN_WBWA    (1 << 3)
  29 #define TTB_RGN_WT      (2 << 3)
  30 #define TTB_RGN_WB      (3 << 3)
  31
  32 #ifndef CONFIG_SMP
  33 #define TTB_FLAGS       TTB_RGN_WBWA
  34 #else
  35 #define TTB_FLAGS       TTB_RGN_WBWA|TTB_S
  36 #endif
  37
  38 ENTRY(cpu_v6_proc_init)
  39         mov     pc, lr
  40
  41 ENTRY(cpu_v6_proc_fin)
  42         stmfd   sp!, {lr}
  43         cpsid   if                              @ disable interrupts
  44         bl      v6_flush_kern_cache_all
  45         mrc     p15, 0, r0, c1, c0, 0           @ ctrl register
  46         bic     r0, r0, #0x1000                 @ ...i............
  47         bic     r0, r0, #0x0006                 @ .............ca.
  48         mcr     p15, 0, r0, c1, c0, 0           @ disable caches
  49         ldmfd   sp!, {pc}
  50
  51 /*
  52  *      cpu_v6_reset(loc)
  53  *
  54  *      Perform a soft reset of the system.  Put the CPU into the
  55  *      same state as it would be if it had been reset, and branch
  56  *      to what would be the reset vector.
  57  *
  58  *      - loc   - location to jump to for soft reset
  59  *
  60  *      It is assumed that:
  61  */
  62         .align  5
  63 ENTRY(cpu_v6_reset)
  64         mov     pc, r0
  65
  66 /*
  67  *      cpu_v6_do_idle()
  68  *
  69  *      Idle the processor (eg, wait for interrupt).
  70  *
  71  *      IRQs are already disabled.
  72  */
  73 ENTRY(cpu_v6_do_idle)
  74         mcr     p15, 0, r1, c7, c0, 4           @ wait for interrupt
  75         mov     pc, lr
  76
  77 ENTRY(cpu_v6_dcache_clean_area)
  78 #ifndef TLB_CAN_READ_FROM_L1_CACHE
  79 1:      mcr     p15, 0, r0, c7, c10, 1          @ clean D entry
  80         add     r0, r0, #D_CACHE_LINE_SIZE
  81         subs    r1, r1, #D_CACHE_LINE_SIZE
  82         bhi     1b
  83 #endif
  84         mov     pc, lr
  85
  86 /*
  87  *      cpu_arm926_switch_mm(pgd_phys, tsk)
  88  *
  89  *      Set the translation table base pointer to be pgd_phys
  90  *
  91  *      - pgd_phys - physical address of new TTB
  92  *
  93  *      It is assumed that:
  94  *      - we are not using split page tables
  95  */
  96 ENTRY(cpu_v6_switch_mm)
  97 #ifdef CONFIG_MMU
  98         mov     r2, #0
  99         ldr     r1, [r1, #MM_CONTEXT_ID]        @ get mm->context.id
 100         orr     r0, r0, #TTB_FLAGS
 101         mcr     p15, 0, r2, c7, c5, 6           @ flush BTAC/BTB
 102         mcr     p15, 0, r2, c7, c10, 4          @ drain write buffer
 103         mcr     p15, 0, r0, c2, c0, 0           @ set TTB 0
 104         mcr     p15, 0, r1, c13, c0, 1          @ set context ID
 105 #endif
 106         mov     pc, lr
 107
 108 /*
 109  *      cpu_v6_set_pte_ext(ptep, pte, ext)
 110  *
 111  *      Set a level 2 translation table entry.
 112  *
 113  *      - ptep  - pointer to level 2 translation table entry
 114  *                (hardware version is stored at -1024 bytes)
 115  *      - pte   - PTE value to store
 116  *      - ext   - value for extended PTE bits
 117  */
 118 ENTRY(cpu_v6_set_pte_ext)
 119 #ifdef CONFIG_MMU
 120         armv6_set_pte_ext
 121 #endif
 122         mov     pc, lr
 123
 124
 125
 126
 127 cpu_v6_name:
 128         .asciz  "ARMv6-compatible processor"
 129         .align
 130
 131         .section ".text.init", #alloc, #execinstr
 132
 133 /*
 134  *      __v6_setup
 135  *
 136  *      Initialise TLB, Caches, and MMU state ready to switch the MMU
 137  *      on.  Return in r0 the new CP15 C1 control register setting.
 138  *
 139  *      We automatically detect if we have a Harvard cache, and use the
 140  *      Harvard cache control instructions insead of the unified cache
 141  *      control instructions.
 142  *
 143  *      This should be able to cover all ARMv6 cores.
 144  *
 145  *      It is assumed that:
 146  *      - cache type register is implemented
 147  */
 148 __v6_setup:
 149 #ifdef CONFIG_SMP
 150         mrc     p15, 0, r0, c1, c0, 1           @ Enable SMP/nAMP mode
 151         orr     r0, r0, #0x20
 152         mcr     p15, 0, r0, c1, c0, 1
 153 #endif
 154
 155         mov     r0, #0
 156         mcr     p15, 0, r0, c7, c14, 0          @ clean+invalidate D cache
 157         mcr     p15, 0, r0, c7, c5, 0           @ invalidate I cache
 158         mcr     p15, 0, r0, c7, c15, 0          @ clean+invalidate cache
 159         mcr     p15, 0, r0, c7, c10, 4          @ drain write buffer
 160 #ifdef CONFIG_MMU
 161         mcr     p15, 0, r0, c8, c7, 0           @ invalidate I + D TLBs
 162         mcr     p15, 0, r0, c2, c0, 2           @ TTB control register
 163         orr     r4, r4, #TTB_FLAGS
 164         mcr     p15, 0, r4, c2, c0, 1           @ load TTB1
 165 #endif /* CONFIG_MMU */
 166         adr     r5, v6_crval
 167         ldmia   r5, {r5, r6}
 168         mrc     p15, 0, r0, c1, c0, 0           @ read control register
 169         bic     r0, r0, r5                      @ clear bits them
 170         orr     r0, r0, r6                      @ set them
 171         mov     pc, lr                          @ return to head.S:__ret
 172
 173         /*
 174          *         V X F   I D LR
 175          * .... ...E PUI. .T.T 4RVI ZFRS BLDP WCAM
 176          * rrrr rrrx xxx0 0101 xxxx xxxx x111 xxxx < forced
 177          *         0 110       0011 1.00 .111 1101 < we want
 178          */
 179         .type   v6_crval, #object
 180 v6_crval:
 181         crval   clear=0x01e0fb7f, mmuset=0x00c0387d, ucset=0x00c0187c
 182
 183         .type   v6_processor_functions, #object
 184 ENTRY(v6_processor_functions)
 185         .word   v6_early_abort
 186         .word   pabort_noifar
 187         .word   cpu_v6_proc_init
 188         .word   cpu_v6_proc_fin
 189         .word   cpu_v6_reset
 190         .word   cpu_v6_do_idle
 191         .word   cpu_v6_dcache_clean_area
 192         .word   cpu_v6_switch_mm
 193         .word   cpu_v6_set_pte_ext
 194         .size   v6_processor_functions, . - v6_processor_functions
 195
 196         .type   cpu_arch_name, #object
 197 cpu_arch_name:
 198         .asciz  "armv6"
 199         .size   cpu_arch_name, . - cpu_arch_name
 200
 201         .type   cpu_elf_name, #object
 202 cpu_elf_name:
 203         .asciz  "v6"
 204         .size   cpu_elf_name, . - cpu_elf_name
 205         .align
 206
 207         .section ".proc.info.init", #alloc, #execinstr
 208
 209         /*
 210          * Match any ARMv6 processor core.
 211          */
 212         .type   __v6_proc_info, #object
 213 __v6_proc_info:
 214         .long   0x0007b000
 215         .long   0x0007f000
 216         .long   PMD_TYPE_SECT | \
 217                 PMD_SECT_BUFFERABLE | \
 218                 PMD_SECT_CACHEABLE | \
 219                 PMD_SECT_AP_WRITE | \
 220                 PMD_SECT_AP_READ
 221         .long   PMD_TYPE_SECT | \
 222                 PMD_SECT_XN | \
 223                 PMD_SECT_AP_WRITE | \
 224                 PMD_SECT_AP_READ
 225         b       __v6_setup
 226         .long   cpu_arch_name
 227         .long   cpu_elf_name
 228         .long   HWCAP_SWP|HWCAP_HALF|HWCAP_THUMB|HWCAP_FAST_MULT|HWCAP_EDSP|HWCAP_JAVA
 229         .long   cpu_v6_name
 230         .long   v6_processor_functions
 231         .long   v6wbi_tlb_fns
 232         .long   v6_user_fns
 233         .long   v6_cache_fns
 234         .size   __v6_proc_info, . - __v6_proc_info